6-7-2 描画形状が□、◇、他
6-7-2-1 Guyou
【 投影式 】cos a = [cos φ sin (λ - λ0) - sin φ] / 21/2
cos b = [cos φ sin (λ - λ0) + sin φ] / 21/2
sin m = ± (1 + cos a cos b - sin a sin b )1/2
↑符号は ( λ - λ0)
sin n = ± (1 - cos a cos b - sin a sin b )1/2
↑符号はφ
x = R∫0m(1 - 0.5 sin2m)-1/2dm
y = R∫0n(1 - 0.5 sin2n)-1/2dn
もし |φ| = π/2
x = 0
y = ± 1.841239209 R
↑ 符号はφ、参考にした文献では 1.85407だが、
簡易積分のせいか |φ| = π/2 → ±90°のポ
イントだけ髭のように飛び出るるため補正
した。
数値は、後述する 6-7-2-4-3 の算出値を
用いた。
【経度・緯度】 経線:曲線 、緯線:曲線
【 ポイント 】・投影式の中に積分が含まれていますが、EXCELには標準
装備されていません。VBAなどで算出する方法もありま
すが、私は、シンプソンの公式を利用して簡易積分を
して見ました。
∫abf(x)dx=[(b−a)/6]{f(a)+4 f [(a+b)/2]+f(b)}
発生します。端っこの経線などで起こる可能性がありま
した。そのポイントは、経度か緯度を微調整してくだ
さい。
<例>
経度 緯度
45° 58° ←エラー発生
45° 58.000001°←エラー回避
・描画は半球が四角形で投影されます。ここでは、並列の
描画例を記載しました。
・補助線の端経線の緯度に緯度±45°の点が該当すると思
ったのですが、これも簡易積分のせいか右上隅だけの
y が、やや小さい数値となります。
そこで、端経線を四角にするためには、45°と46°の間に
特別な緯度を挿入します。下記は、中心経度が 135°の
場合の例です。
経度 緯度 経度 緯度
-135° 46° -135° 46°
-135° 45° →→ -135° 45.00006°
-135° 44° -135° 45°
-135° 44°
勿論、並列や縦列にしない場合は、見た目上は、判別でき
ない程の差てすので、挿入しなくてもよいでしょう。
<基準経度・標準緯度・予備計算・共通数値 など> | ||||||||||||||||||||||||||||||||||||
記号 | セルNo. | 記述式 | ||||||||||||||||||||||||||||||||||
λ0 | C2 | ??? ← 中心経度(希望経度を入力) | ||||||||||||||||||||||||||||||||||
R | C3 | 1 | ||||||||||||||||||||||||||||||||||
<データ計算 など> 経度緯度のデータ毎に記述式を複写(行コピー)する。 | ||||||||||||||||||||||||||||||||||||
記号 | セルNo. | 記述式 | ||||||||||||||||||||||||||||||||||
No. | B9 | ??? ← 式を複写する時に、一旦ソートしたり、解析時に役立つので連番号を付与 | ||||||||||||||||||||||||||||||||||
経度 | C9 | ??? ← 実際の経度データ | ||||||||||||||||||||||||||||||||||
緯度 | D9 | ??? ← 実際の緯度データ | ||||||||||||||||||||||||||||||||||
補正 λ-λ0 |
E9 |
=IF($C$2<0,IF(C9-$C$2>180,C9-$C$2-360,C9-$C$2), IF(C9-$C$2<-180,C9+360-$C$2,C9-$C$2)) |
||||||||||||||||||||||||||||||||||
a | F9 | =ACOS((COS(RADIANS(D9))*SIN(RADIANS(E9))-SIN(RADIANS(D9)))/SQRT(2)) | ||||||||||||||||||||||||||||||||||
b | G9 | =ACOS((COS(RADIANS(D9))*SIN(RADIANS(E9))+SIN(RADIANS(D9)))/SQRT(2)) | ||||||||||||||||||||||||||||||||||
m | H9 | =ASIN(SIGN(E9)*SQRT(1+COS(F9)*COS(G9)-SIN(F9)*SIN(G9))) | ||||||||||||||||||||||||||||||||||
n | I9 | =ASIN(SIGN(D9)*SQRT(1-COS(F9)*COS(G9)-SIN(F9)*SIN(G9))) | ||||||||||||||||||||||||||||||||||
x | J9 |
=IF(ABS(RADIANS(D9))=PI()/2,0,((1-0.5*(SIN(0))^2)^(-1/2)+ 4*((1-0.5*(SIN(H9/2))^2)^(-1/2))+(1-0.5*(SIN(H9))^2)^(-1/2))*H9/6) |
||||||||||||||||||||||||||||||||||
y | K9 |
=IF(ABS(RADIANS(D9))=PI()/2,IF(D9<0,-1.85407,1.85407), ((1-0.5*(SIN(0))^2)^(-1/2)+4*((1-0.5*(SIN(I9/2))^2)^(-1/2))+ (1-0.5*(SIN(I9))^2)^(-1/2))*I9/6) |
||||||||||||||||||||||||||||||||||
[図 6-7-2-1] Guyou 図法 ( Guyou Projection )
【地図主点(中心)】東経 135゚、緯度 0゚ 【経度間隔】15゚ 【緯度間隔】10゚
【備考】投影式の積分は、シンプソンの公式を利用した簡易積分を実施
[図 6-7-2-1] Guyou 図法 - 四角並列 ( Guyou Projection )
【地図主点(中心)】左:東経 135゚、緯度 0゚ 右:西経 45゚、緯度 0゚
【経度間隔】15゚ 【緯度間隔】10゚
【備考】投影式の積分は、シンプソンの公式を利用した簡易積分を実施
[図 6-7-2-1] Guyou 図法 - 四角縦列 ( Guyou Projection )
【地図主点(中心)】東経 135゚、緯度 90゚
【経度間隔】15゚ 【緯度間隔】10゚
【備考】投影式の積分は、シンプソンの公式を利用した簡易積分を実施
6-7-2-2 Armadillo
【 投影式 】x = R (1 + cosφ) sin [(λ - λ0)/2]
y = R { (1 + sin φ0 - cos φ0)/2 + sin φ cos φ0 –
(1 + cosφ) sin φ0 cos[(λ- λ0)/2)]}
φS = - arctan {cos[(λ - λ0)/2] / tan φ0} ←描画境界値
【経度・緯度】 経線:曲線 、緯線:曲線
【 ポイント 】・φ0を変えると視点が変化します。
<基準経度・標準緯度・予備計算・共通数値 など> | ||||||||||||||||||||||||||||||||||||
記号 | セルNo. | 記述式 | ||||||||||||||||||||||||||||||||||
λ0 | C2 | ??? ← 中心経度(希望経度を入力) | ||||||||||||||||||||||||||||||||||
φ0 | C3 | ?? ←視点緯度 | ||||||||||||||||||||||||||||||||||
R | C4 | 1 | ||||||||||||||||||||||||||||||||||
<予備計算・共通数値 など> | ||||||||||||||||||||||||||||||||||||
記号 | セルNo. | 記述式 | ||||||||||||||||||||||||||||||||||
sin φ0 | G2 | =SIN(RADIANS($C$3)) | ||||||||||||||||||||||||||||||||||
cos φ0 | G3 | =COS(RADIANS($C$3)) | ||||||||||||||||||||||||||||||||||
(1 + sin φ0 - cos φ0 )/2 | G4 | =(1+G2-G3)/2 | ||||||||||||||||||||||||||||||||||
tan φ0 | G5 | =TAN(RADIANS($C$3)) | ||||||||||||||||||||||||||||||||||
<データ計算 など> 経度緯度のデータ毎に記述式を複写(行コピー)する。 | ||||||||||||||||||||||||||||||||||||
記号 | セルNo. | 記述式 | ||||||||||||||||||||||||||||||||||
No. | B9 | ??? ← 式を複写する時に、一旦ソートしたり、解析時に役立つので連番号を付与 | ||||||||||||||||||||||||||||||||||
経度 | C9 | ??? ← 実際の経度データ | ||||||||||||||||||||||||||||||||||
緯度 | D9 | ??? ← 実際の緯度データ | ||||||||||||||||||||||||||||||||||
補正 λ-λ0 |
E9 |
=IF($C$2<0,IF(C9-$C$2>180,C9-$C$2-360,C9-$C$2), IF(C9-$C$2<-180,C9+360-$C$2,C9-$C$2)) |
||||||||||||||||||||||||||||||||||
φS | F9 | =DEGREES(-ATAN(COS(RADIANS((E9)/2))/TAN($G$5))) | ||||||||||||||||||||||||||||||||||
x | G9 | =(1+COS(RADIANS(D9)))*SIN(RADIANS((E9)/2)) | ||||||||||||||||||||||||||||||||||
y | H9 |
=$G$4+SIN(RADIANS(D9))*$G$3- (1+COS(RADIANS(D9)))*$G$2*COS(RADIANS((E9)/2)) |
||||||||||||||||||||||||||||||||||
描画CH | I9 | =IF(D9<F9,"●",0) | ||||||||||||||||||||||||||||||||||
端CH | J10 |
=IF(G10="",0,IF(AND(ABS(G10)>0.2,G9*G10<0),"●",IF(AND(G9<>"", G10>PI()/2,ABS(G9-G10)>0.2),"●",0))) |
||||||||||||||||||||||||||||||||||
↑ 左右の端をチェックしている。"●"の付いた行の前に一行挿入すると、勝手に左端と右端が線で結ばれない。 |
[図 6-7-2-2] アルマジロ図法 ( Armadillo projection )
【地図主点(中心)経度】東経 135゚ 【傾斜角】20゚ 【経度間隔】15゚ 【緯度間隔】10゚
6-7-2-3 HEALPix Projection
【 投影式 】中央部
x = λ
y = ( 3π / 2H ) sinφ
極地域
σ = ( 3 ( 1 - | sinφ| ) )1/2
λc = - π + ( 2 ( ( λ+π ) H ) / 2π ) + 1 ) π / H ⇒ λ+π/H
x = λc + ( λ - λc ) σ
y = ± ( π / H ) ( 2 - σ ) ←符号は φ
【経度・緯度】 経線:直線 、緯線:直線
【 ポイント 】K = 3 , H = 4 で描画するものとして説明します。
・北緯41.8103゚~ 南緯41.8103゚, 西経180゚~北緯180゚の
範囲は中央部として描画し、形状は四角です(ブロック
イメージ図の⑤)。
・北緯41.8103゚以北と南緯41.8103゚以南の範囲は、三角形の
形状として描画されます。北半球と南半球を各々4つに
分けておきます(ブロックイメージ図の①-N~④-N ,
①-S~④-S)。
ブロックのイメージ図
<基準経度・標準緯度・予備計算・共通数値 など> | ||||||||||||||||||||||||||||||||||||
記号 | セルNo. | 記述式 | ||||||||||||||||||||||||||||||||||
K | C2 | 3 | ||||||||||||||||||||||||||||||||||
H | C3 | 4 | ||||||||||||||||||||||||||||||||||
φx | C4 | =DEGREES(ASIN(2/3)) ← 境界緯度 sin-1(2/3) = 41.8103゚ | ||||||||||||||||||||||||||||||||||
<境界区域数値 など> ※描画左端を -180°にした例です。 | ||||||||||||||||||||||||||||||||||||
記号 | セルNo. | 記述式 | ||||||||||||||||||||||||||||||||||
区域 ① 左端経度 | G2 | -180 | ||||||||||||||||||||||||||||||||||
区域 ② 左端経度 | G3 | =G2+90 = -90 | ||||||||||||||||||||||||||||||||||
区域 ③ 左端経度 | G4 | =G3+90 = 0 | ||||||||||||||||||||||||||||||||||
区域 ④ 左端経度 | G5 | =G4+90 = 90 ← この区域の中央が東経135°となる | ||||||||||||||||||||||||||||||||||
区域 ① の λC | H2 | =RADIANS(G2)+PI()/$C$3 | ||||||||||||||||||||||||||||||||||
区域 ② の λC | H3 | =RADIANS(G3)+PI()/$C$3 | ||||||||||||||||||||||||||||||||||
区域 ③ の λC | H4 | =RADIANS(G4)+PI()/$C$3 | ||||||||||||||||||||||||||||||||||
区域 ④ の λC | H5 | =RADIANS(G5)+PI()/$C$3 | ||||||||||||||||||||||||||||||||||
<データ計算 など> 経度緯度のデータ毎に記述式を複写(行コピー)する。 | ||||||||||||||||||||||||||||||||||||
区分 | 記号 | セルNo. | 記述式 | |||||||||||||||||||||||||||||||||
中 央 部 ⑤ |
No. | B9 | ??? ← 式の複写時、一旦ソートしたり,解析時に役立つので連番号を付与 | |||||||||||||||||||||||||||||||||
経度 | C9 | ??? ← 実際の経度データ | ||||||||||||||||||||||||||||||||||
緯度 | D9 | ??? ← 実際の緯度データ | ||||||||||||||||||||||||||||||||||
x | E9 | =RADIANS(C9) | ||||||||||||||||||||||||||||||||||
y | F9 | =(3*PI()/(2*$C$3))*SIN(RADIANS(D9)) | ||||||||||||||||||||||||||||||||||
区 域 ① |
No. | G9 | ??? ← 式の複写時、一旦ソートしたり,解析時に役立つので連番号を付与 | |||||||||||||||||||||||||||||||||
経度 | H9 | ??? ← 実際の経度データ | ||||||||||||||||||||||||||||||||||
緯度 | I9 | ??? ← 実際の緯度データ | ||||||||||||||||||||||||||||||||||
σ | J9 | =SQRT(3*(1-ABS(SIN(RADIANS(I9))))) | ||||||||||||||||||||||||||||||||||
x | K9 | =$H$2+(RADIANS(H9)-$H$2)*J9 | ||||||||||||||||||||||||||||||||||
y | L9 | =SIGN(I9)*(PI()/$C$3)*(2-J9) | ||||||||||||||||||||||||||||||||||
↑ 区域②~④は 上表の λc ($H$2)を変更すれば良い。 |
[図 6-7-2-3] HEALPix 図法 ( HEALPix Projection )
【地図主点(中心)】東経 0゚、緯度 0゚ 【経度間隔】15゚ 【緯度間隔】10゚
【パラメータ】H = 4 , K = 3
6-7-2-4 Adams Hemisphere in a Square
【 投影式 】cos a = cos φ sin (λ - λ0)
b = π / 2 - φ
sin m = ±(1 + cos a cos b - sin a sin b )1/2
↑符号は (sinφ+ cos α)
sin n = ±(1 - cos a cos b - sin a sin b )1/2
↑符号は (sinφ- cos α)
x = R ∫0m (1 - 0.5 sin2m)-1/2dm
y = R ∫0n (1 - 0.5 sin2n)-1/2dn
もし |φ| = π / 2 ,
x & y = ± 1.841239209 R
↑ 符号はφ、参考にした文献では
1.85407だが、簡易積分のせいか
並列連結時、隙間ができるためため
補正した。数値は、実際の描画端の
経度緯度を算出してこの値に決めた。
【経度・緯度】 経線:曲線 、緯線:曲線
【 ポイント 】・中心経度±90°の正方形となるが、中心経度が45°傾い
ている。ここでは、半球描画を並列にしたものと45°回転
させたひし形を並列にしたものを描画してみる。
・積分はシンプソンの公式を利用した簡易積分を行った。
・データは、左半球と右半球に分けておきます。
・投影式の中に積分が含まれていますが、シンプソンの公式を
利用して簡易積分をして見ました。
・簡易積分のせいか、補助線などでエラーなるポイントが発生
します。端っこの経線などで起こる可能性がありました。
そのポイントは、経度か緯度を微調整してください。
<例>
緯度
16° ←エラー発生
16.000001°←エラー回避
①四角並列 ( □+□ ) ← □ は描画形状四角をイメージしています
右半球の □ は、投影式で算出後 x の符号を反転させ、□ の幅を加算して用いる。
<基準経度・標準緯度・予備計算・共通数値 など> | ||||||||||||||||||||||||||||||||||||
記号 | セルNo. | 記述式 | ||||||||||||||||||||||||||||||||||
λ0 | C2 | ??? ← 中心経度(希望経度を入力) | ||||||||||||||||||||||||||||||||||
R | C3 | 1 |
【右半球の
□ へのシフト値計算】
左半球の □ を描画してみると左図
A、B の長さを算出し、シフトさせれ
ば良いことが判る
●経度
・A、B点:中心経度 - 90°
例:中心 135°→ 45°
●緯度
・A点: 0°
・B点:90°(北緯)
<シフト値を計算する> | ||||||||||||||||||||||||||||||||||||
記号 | セルNo. | 記述式 | ||||||||||||||||||||||||||||||||||
経度 | G3 | 45 | ||||||||||||||||||||||||||||||||||
緯度 | H3 | 90 | ||||||||||||||||||||||||||||||||||
補正 λ-λ0 |
I3 |
=IF($C$2<0,IF(G3-$C$2>180,G3-$C$2-360,G3-$C$2), IF(G3-$C$2<-180,G3+360-$C$2,G3-$C$2)) |
||||||||||||||||||||||||||||||||||
a | J3 | =ACOS(COS(RADIANS(H3))*SIN(RADIANS(I3))) | ||||||||||||||||||||||||||||||||||
b | K3 | =PI()/2-RADIANS(H3) | ||||||||||||||||||||||||||||||||||
m | L3 |
=ASIN(SIGN(SIN(RADIANS(H3))+COS(J3))* SQRT(1+COS(J3)*COS(K3)-SIN(J3)*SIN(K3))) |
||||||||||||||||||||||||||||||||||
n | M3 |
=ASIN(SIGN(SIN(RADIANS(H3))-COS(J3))* SQRT(1-COS(J3)*COS(K3)-SIN(J3)*SIN(K3))) |
||||||||||||||||||||||||||||||||||
x 左の 左端 |
N3 |
=IF(ABS(RADIANS(H3))=PI()/2,SIGN(H3)*1.841239209, ((1-0.5*(SIN(0))^2)^(-1/2)+4*((1-0.5*(SIN(L3/2))^2)^(-1/2))+(1-0.5*(SIN(L3))^2)^(-1/2))*L3/6) |
||||||||||||||||||||||||||||||||||
経度 | G4 | 45 | ||||||||||||||||||||||||||||||||||
緯度 | H4 | 0 | ||||||||||||||||||||||||||||||||||
補正 λ-λ0 |
I4 |
=IF($C$2<0,IF(G4-$C$2>180,G4-$C$2-360,G4-$C$2), IF(G4-$C$2<-180,G4+360-$C$2,G4-$C$2)) |
||||||||||||||||||||||||||||||||||
a | J4 | =ACOS(COS(RADIANS(H4))*SIN(RADIANS(I4))) | ||||||||||||||||||||||||||||||||||
b | K4 | =PI()/2-RADIANS(H4) | ||||||||||||||||||||||||||||||||||
m | L4 |
=ASIN(SIGN(SIN(RADIANS(H4))+COS(J4))* SQRT(1+COS(J4)*COS(K4)-SIN(J4)*SIN(K4))) |
||||||||||||||||||||||||||||||||||
n | M4 |
=ASIN(SIGN(SIN(RADIANS(H4))-COS(J4))* SQRT(1-COS(J4)*COS(K4)-SIN(J4)*SIN(K4))) |
||||||||||||||||||||||||||||||||||
x 左の 右端 |
N4 |
=IF(ABS(RADIANS(H4))=PI()/2,SIGN(H4)*1.841239209, ((1-0.5*(SIN(0))^2)^(-1/2)+4*((1-0.5*(SIN(L4/2))^2)^(-1/2))+(1-0.5*(SIN(L4))^2)^(-1/2))*L4/6) |
||||||||||||||||||||||||||||||||||
シフト値 | O4 |
=N3-N4 ←シフト値 ↖ = 3.68247841780183 ← この値は、中心経度を変えても変化しません。 |
||||||||||||||||||||||||||||||||||
<データ計算 など> 経度緯度のデータ毎に記述式を複写(行コピー)する。 | ||||||||||||||||||||||||||||||||||||
区分 | 記号 | セルNo. | 記述式 | |||||||||||||||||||||||||||||||||
左 半 球 |
No. | B9 | ??? ← 式の複写時、一旦ソートしたり,解析時に役立つので連番号を付与 | |||||||||||||||||||||||||||||||||
経度 | C9 | ??? ← 実際の経度データ | ||||||||||||||||||||||||||||||||||
緯度 | D9 | ??? ← 実際の緯度データ | ||||||||||||||||||||||||||||||||||
補正 λ-λ0 |
E9 |
=IF($C$2<0,IF(C9-$C$2>180,C9-$C$2-360,C9-$C$2), IF(C9-$C$2<-180,C9+360-$C$2,C9-$C$2)) |
||||||||||||||||||||||||||||||||||
a | F9 | =ACOS(COS(RADIANS(D9))*SIN(RADIANS(E9))) | ||||||||||||||||||||||||||||||||||
b | G9 | =PI()/2-RADIANS(D9) | ||||||||||||||||||||||||||||||||||
m | H9 |
=ASIN(SIGN(SIN(RADIANS(D9))+COS(F9))* SQRT(1+COS(F9)*COS(G9)-SIN(F9)*SIN(G9))) |
||||||||||||||||||||||||||||||||||
n | I9 |
=ASIN(SIGN(SIN(RADIANS(D9))-COS(F9))* SQRT(1-COS(F9)*COS(G9)-SIN(F9)*SIN(G9))) |
||||||||||||||||||||||||||||||||||
x 左 | J9 |
=IF(ABS(RADIANS(D9))=PI()/2,SIGN(D9)* 1.841239209,((1-0.5*(SIN(0))^2)^(-1/2)+4* ((1-0.5*(SIN(H9/2))^2)^(-1/2))+(1-0.5*(SIN(H9))^2)^(-1/2))*H9/6) |
||||||||||||||||||||||||||||||||||
y 左 | K9 |
=IF(ABS(RADIANS(D9))=PI()/2,SIGN(D9)* 1.841239209,((1-0.5*(SIN(0))^2)^(-1/2)+ 4*((1-0.5*(SIN(I9/2))^2)^(-1/2))+(1-0.5*(SIN(I9))^2)^(-1/2))*I9/6) |
||||||||||||||||||||||||||||||||||
右 半 球 |
No. | L9 | ??? ← 式の複写時、一旦ソートしたり,解析時に役立つので連番号を付与 | |||||||||||||||||||||||||||||||||
経度 | M9 | ??? ← 実際の経度データ | ||||||||||||||||||||||||||||||||||
緯度 | N9 | ??? ← 実際の緯度データ | ||||||||||||||||||||||||||||||||||
補正 λ-λ0 |
O9 |
=IF($C$2<0,IF(M9-$C$2>180,M9-$C$2-360,M9-$C$2), IF(M9-$C$2<-180,M9+360-$C$2,M9-$C$2)) |
||||||||||||||||||||||||||||||||||
a | P9 | =ACOS(COS(RADIANS(N9))*SIN(RADIANS(O9))) | ||||||||||||||||||||||||||||||||||
b | Q9 | =PI()/2-RADIANS(N9) | ||||||||||||||||||||||||||||||||||
m | R9 |
=ASIN(SIGN(SIN(RADIANS(N9))+COS(P9))* SQRT(1+COS(P9)*COS(Q9)-SIN(P9)*SIN(Q9))) |
||||||||||||||||||||||||||||||||||
n | S9 |
=ASIN(SIGN(SIN(RADIANS(N9))-COS(P9))* SQRT(1-COS(P9)*COS(Q9)-SIN(P9)*SIN(Q9))) |
||||||||||||||||||||||||||||||||||
x 右 | T9 |
=-IF(ABS(RADIANS(N9))=PI()/2,SIGN(N9)*1.841239209, ((1-0.5*(SIN(0))^2)^(-1/2)+4*((1-0.5*(SIN(R9/2))^2)^(-1/2))+ (1-0.5*(SIN(R9))^2)^(-1/2))*R9/6)+$O$4 |
||||||||||||||||||||||||||||||||||
y 右 | U9 |
=IF(ABS(RADIANS(N9))=PI()/2,SIGN(N9)* 1.841239209,((1-0.5*(SIN(0))^2)^(-1/2)+ 4*((1-0.5*(SIN(S9/2))^2)^(-1/2))+(1-0.5*(SIN(S9))^2)^(-1/2))*S9/6) |
||||||||||||||||||||||||||||||||||
[図 6-7-2-4] Adams Hemisphere in a Square 図法
( Adams Hemisphere in a Square Projection )
【地図主点(中心)】東経 135゚、緯度 0゚
【経度間隔】15゚ 【緯度間隔】10゚
【備考】投影式の積分は、シンプソンの公式を利用した簡易積分を実施
[図 6-7-2-4] Adams Hemisphere in a Square 図法 - 四角並列
( Adams Hemisphere in a Square Projection )
【地図主点(中心)】左:東経 135゚、緯度 0゚ 右:西経 45゚、緯度 0゚
【経度間隔】15゚ 【緯度間隔】10゚
【備考】投影式の積分は、シンプソンの公式を利用した簡易積分を実施
② ひし形並列 ( ◇+◇ ) ← ◇ は描画形状ひし形をイメージしていま四角(□)を45°
回転させることにより正立させ、ひし形(◇)にし投影する
(1) 標準投影式で x と y を算出する。
(2) 中心から ( x, y ) までの距離を求める。
(3) ( x , y ) への角度を求め、その値に45°(π/4)を加えたθを求める。
(4) さらに (2),(3) に対応する x r と y r を求める。
(5) 右のひし形用は x r は、符号を反転させ、右にシフトさせ
x r右 として算出
【右半球の ◇ へのシフト値計算】
左半球の ◇ を描画してみると左図
A、Cを算出し、右にシフトさせれば
良い。
[ A -- C ] = [ A -- B ] × √2
↖ □ で算出済
=1.841239209 × √2
<基準経度・標準緯度・予備計算・シフト値 など> | ||||||||||||||||||||||||||||||||||||
記号 | セルNo. | 記述式 | ||||||||||||||||||||||||||||||||||
λ0 | C2 | ??? ← 中心経度(希望経度を入力) | ||||||||||||||||||||||||||||||||||
R | C3 | 1 | ||||||||||||||||||||||||||||||||||
□ シフト値 | C4 | 3.68247841780183 ← 前述 □ で算出 | ||||||||||||||||||||||||||||||||||
◇ シフト値 | C5 | =C4*SQRT(2) | ||||||||||||||||||||||||||||||||||
<データ計算 など> 経度緯度のデータ毎に記述式を複写(行コピー)する。 | ||||||||||||||||||||||||||||||||||||
区分 | 記号 | セルNo. | 記述式 | |||||||||||||||||||||||||||||||||
左 半 球 |
No. | B9 | ??? ← 式の複写時、一旦ソートしたり,解析時に役立つので連番号を付与 | |||||||||||||||||||||||||||||||||
経度 | C9 | ??? ← 実際の経度データ | ||||||||||||||||||||||||||||||||||
緯度 | D9 | ??? ← 実際の緯度データ | ||||||||||||||||||||||||||||||||||
補正 λ-λ0 |
E9 |
=IF($C$2<0,IF(C9-$C$2>180,C9-$C$2-360,C9-$C$2), IF(C9-$C$2<-180,C9+360-$C$2,C9-$C$2)) |
||||||||||||||||||||||||||||||||||
a | F9 | =ACOS(COS(RADIANS(D9))*SIN(RADIANS(E9))) | ||||||||||||||||||||||||||||||||||
b | G9 | =PI()/2-RADIANS(D9) | ||||||||||||||||||||||||||||||||||
m | H9 |
=ASIN(SIGN(SIN(RADIANS(D9))+COS(F9))* SQRT(1+COS(F9)*COS(G9)-SIN(F9)*SIN(G9))) |
||||||||||||||||||||||||||||||||||
n | I9 |
=ASIN(SIGN(SIN(RADIANS(D9))-COS(F9))* SQRT(1-COS(F9)*COS(G9)-SIN(F9)*SIN(G9))) |
||||||||||||||||||||||||||||||||||
x 左 (回転前) |
J9 |
=IF(ABS(RADIANS(D9))=PI()/2,SIGN(D9)* 1.841239209,((1-0.5*(SIN(0))^2)^(-1/2)+4* ((1-0.5*(SIN(H9/2))^2)^(-1/2))+(1-0.5*(SIN(H9))^2)^(-1/2))*H9/6) |
||||||||||||||||||||||||||||||||||
y 左 (回転前) |
K9 |
=IF(ABS(RADIANS(D9))=PI()/2,SIGN(D9)* 1.841239209,((1-0.5*(SIN(0))^2)^(-1/2)+ 4*((1-0.5*(SIN(I9/2))^2)^(-1/2))+(1-0.5*(SIN(I9))^2)^(-1/2))*I9/6) |
||||||||||||||||||||||||||||||||||
距離 | L9 | =SQRT(J9^2+K9^2) | ||||||||||||||||||||||||||||||||||
θ | M9 | =ATAN(K9/J9)+PI()/4 | ||||||||||||||||||||||||||||||||||
xr 左 | N9 | =IF(E9=0,0,-SIGN(E9)*IF(M9<PI()/2,-L9*COS(M9),L9*COS(M9))) | ||||||||||||||||||||||||||||||||||
yr 左 | O9 |
=IF(M9=PI()/2,SIGN(D9)*L9,IF(M9<PI()/2,SIGN(E9)* L9*SIN(M9),-SIGN(E9)*L9*SIN(M9))) |
||||||||||||||||||||||||||||||||||
右 半 球 |
No. | P9 | ??? ← 式の複写時、一旦ソートしたり,解析時に役立つので連番号を付与 | |||||||||||||||||||||||||||||||||
経度 | Q9 | ??? ← 実際の経度データ | ||||||||||||||||||||||||||||||||||
緯度 | R9 | ??? ← 実際の緯度データ | ||||||||||||||||||||||||||||||||||
補正 λ-λ0 |
S9 |
=IF($C$2<0,IF(Q9-$C$2>180,Q9-$C$2-360,Q9-$C$2), IF(Q9-$C$2<-180,Q9+360-$C$2,Q9-$C$2)) |
||||||||||||||||||||||||||||||||||
a | T9 | =ACOS(COS(RADIANS(R9))*SIN(RADIANS(S9))) | ||||||||||||||||||||||||||||||||||
b | U9 | =PI()/2-RADIANS(R9) | ||||||||||||||||||||||||||||||||||
m | V9 |
=ASIN(SIGN(SIN(RADIANS(R9))+COS(T9))* SQRT(1+COS(T9)*COS(U9)-SIN(T9)*SIN(U9))) |
||||||||||||||||||||||||||||||||||
n | W9 |
=ASIN(SIGN(SIN(RADIANS(R9))-COS(T9))* SQRT(1-COS(T9)*COS(U9)-SIN(T9)*SIN(U9))) |
||||||||||||||||||||||||||||||||||
x 右 (回転前) |
X9 |
=IF(ABS(RADIANS(R9))=PI()/2,SIGN(R9)* 1.841239209,((1-0.5*(SIN(0))^2)^(-1/2)+ 4*((1-0.5*(SIN(V9/2))^2)^(-1/2))+(1-0.5*(SIN(V9))^2)^(-1/2))*V9/6) |
||||||||||||||||||||||||||||||||||
y 右 (回転前) |
Y9 |
=IF(ABS(RADIANS(R9))=PI()/2,SIGN(R9)* 1.841239209,((1-0.5*(SIN(0))^2)^(-1/2)+ 4*((1-0.5*(SIN(W9/2))^2)^(-1/2))+(1-0.5*(SIN(W9))^2)^(-1/2))*W9/6) |
||||||||||||||||||||||||||||||||||
距離 | Z9 | =SQRT(X9^2+Y9^2) | ||||||||||||||||||||||||||||||||||
θ | AA9 | =ATAN(Y9/X9)+PI()/4 | ||||||||||||||||||||||||||||||||||
xr 右 | AB9 | =-IF(S9=0,0,-SIGN(S9)*IF(AA9<PI()/2,-Z9*COS(AA9),Z9*COS(AA9)))+$C$5 | ||||||||||||||||||||||||||||||||||
yr 右 | AC9 |
=IF(AA9=PI()/2,SIGN(R9)*Z9,IF(AA9<PI()/2,SIGN(S9)* Z9*SIN(AA9),-SIGN(S9)*Z9*SIN(AA9))) |
||||||||||||||||||||||||||||||||||
[図 6-7-2-4] Adams Hemisphere in a Square 図法 – ひし形
( Adams Hemisphere in a Square Projection )
【地図主点(中心)】東経 135゚、緯度 0゚
【経度間隔】15゚ 【緯度間隔】10゚
【備考】・投影式の積分は、シンプソンの公式を利用した簡易積分を実施。
・投影式より描画すると斜め45°傾くため、計算式を作成し、正立させた。
[図 6-7-2-4] Adams Hemisphere in a Square 図法 – ひし形並列
( Adams Hemisphere in a Square Projection )
【地図主点(中心)】左:東経 135゚、緯度 0゚ 右:西経 45゚、緯度 0゚
【経度間隔】15゚ 【緯度間隔】10゚
【備考】・投影式の積分は、シンプソンの公式を利用した簡易積分を実施。
・投影式より描画すると斜め45°傾くため、計算式を作成し、正立させた。
6-7-2-5 Peirce Quincuncial
【 投影式 】cos a = cos φ [sin (λ - λ0) + cos (λ - λ0)] / 21/2
cos b = cos φ [sin (λ - λ0) - cos (λ - λ0)] / 21/2
sin m = ± (1 + cos a cos b - sin a sin b )1/2
↑符号は sin( λ - λ0)
sin n = ± (1 - cos a cos b - sin a sin b )1/2
↑ 符号は cos( λ - λ0) の逆
x = R ∫0m (1 - 0.5 sin2m)-1/2dm
y = R ∫0n (1 - 0.5 sin2n)-1/2dn
もし |φ| = π/2 , x = 0 , y = ±1.841239209 R ←符号はφ
【経度・緯度】 経線:曲線 、緯線:曲線
【 ポイント 】・極を中心とした半球を四角形で投影。残りの半球部分をまわりに
配置することにより、全球を正方形に収めることができる。
その正方形をタイルのように敷き詰めることができる。
・投影式の中に積分が含まれていますが、シンプソンの公式を利用
して簡易積分をして見ました。
・簡易積分のせいか、補助線などでエラーなるポイントが発生します。
端っこの緯線などで起こる可能性がありました。そのポイントは、
経度か緯度を微調整してください。
<例>
緯度 62° ←エラー発生
62000001°←エラー回避
6-7-2-5-①半球を正方形に描画し、縦列に配置して描画する。
【下半球の □ へのシフト値計算】
上半球の □ を描画してみると左図
A、B の長さを算出し、シフトさせれ
ば良いことが判る
●A点 ・経度:中心経度 - 135°
例:中心 135°→ 0°
・緯度: 0°
●B点 ・経度:中心経度 - 45°
例:中心 135°→ 90°
・緯度: 0°
実際に計算して見ると、シフト値は
3.68247841780183 となる。
この値は、中心経度を変えても変化しません。
<基準経度・標準緯度・予備計算・共通数値 など> | ||||||||||||||||||||||||||||||||||||
記号 | セルNo. | 記述式 | ||||||||||||||||||||||||||||||||||
λ0 | C2 | ??? ← 中心経度(希望経度を入力) | ||||||||||||||||||||||||||||||||||
R | C3 | 1 | ||||||||||||||||||||||||||||||||||
シフト値 | C4 | =3.68247841780183 ← 前述、説明文参照 | ||||||||||||||||||||||||||||||||||
<データ計算 など> 経度緯度のデータ毎に記述式を複写(行コピー)する。 | ||||||||||||||||||||||||||||||||||||
区分 | 記号 | セルNo. | 記述式 | |||||||||||||||||||||||||||||||||
北 半 球 |
No. | B9 | ??? ← 式の複写時、一旦ソートしたり,解析時に役立つので連番号を付与 | |||||||||||||||||||||||||||||||||
経度 | C9 | ??? ← 実際の経度データ | ||||||||||||||||||||||||||||||||||
緯度 | D9 | ??? ← 実際の緯度データ | ||||||||||||||||||||||||||||||||||
補正 λ-λ0 |
E9 |
=IF($C$2<0,IF(C9-$C$2>180,C9-$C$2-360,C9-$C$2), IF(C9-$C$2<-180,C9+360-$C$2,C9-$C$2)) |
||||||||||||||||||||||||||||||||||
a | F9 |
=ACOS(COS(RADIANS(D9))*(SIN(RADIANS(E9))+ COS(RADIANS(E9)))/SQRT(2)) |
||||||||||||||||||||||||||||||||||
b | G9 |
=ACOS(COS(RADIANS(D9))*(SIN(RADIANS(E9))- COS(RADIANS(E9)))/SQRT(2)) |
||||||||||||||||||||||||||||||||||
m | H9 |
=ASIN(SIGN(SIN(RADIANS(E9)))* SQRT(1+COS(F9)*COS(G9)-SIN(F9)*SIN(G9))) |
||||||||||||||||||||||||||||||||||
n | I9 |
=ASIN(-SIGN(COS(RADIANS(E9)))*SQRT(1- COS(F9)*COS(G9)-SIN(F9)*SIN(G9))) |
||||||||||||||||||||||||||||||||||
x 上 | J9 |
=IF(ABS(RADIANS(D9))=PI()/2,0,((1-0.5*(SIN(0))^2)^(-1/2)+ 4*((1-0.5*(SIN(H9/2))^2)^(-1/2))+(1-0.5*(SIN(H9))^2)^(-1/2))*H9/6) |
||||||||||||||||||||||||||||||||||
y 上 | K9 |
=IF(ABS(RADIANS(D9))=PI()/2,SIGN(D9)* 1.841239,((1-0.5*(SIN(0))^2)^(-1/2)+ 4*((1-0.5*(SIN(I9/2))^2)^(-1/2))+(1-0.5*(SIN(I9))^2)^(-1/2))*I9/6) |
||||||||||||||||||||||||||||||||||
南 半 球 |
No. | L9 | ??? ← 式の複写時、一旦ソートしたり,解析時に役立つので連番号を付与 | |||||||||||||||||||||||||||||||||
経度 | M9 | ??? ← 実際の経度データ | ||||||||||||||||||||||||||||||||||
緯度 | N9 | ??? ← 実際の緯度データ | ||||||||||||||||||||||||||||||||||
補正 λ-λ0 |
O9 |
=IF($C$2<0,IF(M9-$C$2>180,M9-$C$2-360,M9-$C$2), IF(M9-$C$2<-180,M9+360-$C$2,M9-$C$2)) |
||||||||||||||||||||||||||||||||||
a | P9 |
=ACOS(COS(RADIANS(N9))*(SIN(RADIANS(O9))+ COS(RADIANS(O9)))/SQRT(2)) |
||||||||||||||||||||||||||||||||||
b | Q9 |
=ACOS(COS(RADIANS(N9))*(SIN(RADIANS(O9))- COS(RADIANS(O9)))/SQRT(2)) |
||||||||||||||||||||||||||||||||||
m | R9 |
=ASIN(SIGN(SIN(RADIANS(O9)))*SQRT(1+ COS(P9)*COS(Q9)-SIN(P9)*SIN(Q9))) |
||||||||||||||||||||||||||||||||||
n | S9 |
=ASIN(-SIGN(COS(RADIANS(O9)))*SQRT(1- COS(P9)*COS(Q9)-SIN(P9)*SIN(Q9))) |
||||||||||||||||||||||||||||||||||
x 下 | T9 |
=IF(ABS(RADIANS(N9))=PI()/2,0,((1-0.5*(SIN(0))^2)^(-1/2)+ 4*((1-0.5*(SIN(R9/2))^2)^(-1/2))+(1-0.5*(SIN(R9))^2)^(-1/2))*R9/6) |
||||||||||||||||||||||||||||||||||
y 下 | U9 |
=-IF(ABS(RADIANS(N9))=PI()/2,SIGN(N9)* 1.841239,((1-0.5*(SIN(0))^2)^(-1/2)+ 4*((1-0.5*(SIN(S9/2))^2)^(-1/2))+(1-0.5*(SIN(S9))^2)^(-1/2))*S9/6)-$C$4 |
||||||||||||||||||||||||||||||||||
[図 6-7-2-5-①-1] Peirce Quincuncial 図法 ( Peirce Quincuncial Projection )
【地図主点(中心)】東経 135゚、北緯 90゚
【経度間隔】15゚ 【緯度間隔】10゚
【備考】投影式の積分は、シンプソンの公式を利用した簡易積分を実施
[図 6-7-2-5-①-2] Peirce Quincuncial 図法 - 四角縦列 ( Peirce Quincuncial Projection )
【地図主点(中心)】北半球:東経 135゚、北緯 90゚ 南半球:西経 45゚、南緯 90゚
【経度間隔】15゚ 【緯度間隔】10゚
【備考】投影式の積分は、シンプソンの公式を利用した簡易積分を実施
6-7-2-5-②平面充填用のタイル(四角形)を描画する。
正方形に全球を詰め込む。
6-7-2-5-②-1 半球縦列を加工して全球にするタイルを作る
前述半球縦列を180°回転させ、元のものと回転したものを合体させ、平面充填用の
タイルを描画する。出来上がる正方形の緯度0°(赤道)は外周と並行で □形 となる。
<基準経度・標準緯度・予備計算・共通数値 など>
記号 | セルNo. |
記 述 式 |
||||
λ0 | C2 | ??? ← 中心経度(希望経度を入力) | ||||
R | C3 |
1 |
||||
シフト値 | C4 | =3.68247841780183 ← 前述、説明文参照 |
<データ計算 など> 経度緯度のデータ毎に記述式を複写(行コピー)する。
区分 | 記号 | セルNo. |
記 述 式 |
|
北 半 球 |
No. | B9 | 6-7-2-5-①の北半球 No. の値貼付け | |
経度 | C9 |
6-7-2-5-①の北半球 経度の計算値を値貼付け |
||
緯度 | D9 |
6-7-2-5-①の北半球 緯度の計算値を値貼付け |
||
経度回転 | E9 |
=-C9+$C$4 |
||
緯度回転 | F9 |
=-D9-$C$4 |
||
南 半 球 |
No. | G9 |
6-7-2-5-①の南半球 No. の値貼付け |
|
経度 | H9 |
6-7-2-5-①の南半球 経度の計算値を値貼付け |
||
緯度 | I9 |
6-7-2-5-①の南半球 緯度の計算値を値貼付け |
||
経度回転 | J9 |
=-H9+$C$4 |
||
緯度回転 | K9 | =-I9-$C$4 |
[図 6-7-2-5-②-1] Peirce Quincuncial 図法 ( Peirce Quincuncial Projection ) 赤道□
【地図主点(中心)】東経 180゚、緯度 0゚ 【経度間隔】15゚ 【緯度間隔】10゚
【備考】・投影式の積分は、シンプソンの公式を利用した簡易積分を実施。
・平面充填用のタイル(正方形)として用いる。
この平面充填タイルをシフトして上下左右に並べると
6-7-2-5-②-2 半球縦列を加工して全球にし45°傾けたタイルを作る。
6-7-2-5-②-1 では、赤道が平面充填タイルの外周と並行になり単調に見える。そこで
45°傾けた平面充填タイルを検討して見る。回転させた部分は、ある範囲を繰り返し
利用するので、利用範囲に色を付けて説明。
■回転前 [図 6-7-2-5-②-1]
■45°回転(右回り)
■平面充填タイル概要
【 ポイント 】・ 部分シフトを想定して、元のデータを南北半球毎に2つに分けておきます。
<例> 中心経度が 東経135°の場合
(1) 0°~ 180°
(2) -180°~ 0°
※以下の表<データ計算 など>の経度範囲は、この例にフィット
(1)北半球 = 0°~ 180°
(2)北半球 = -180°~ 0°
(1)南半球 = 0°~ 180°
(2)南半球 = -180°~ 0°
<基準経度・標準緯度・予備計算・共通数値 など>
記号 | セルNo. |
記 述 式 |
||||
λ0 | C2 | ??? ← 中心経度(希望経度を入力) | ||||
R | C3 | 1 | ||||
シフト値 1 |
C4 | =3.68247841780183 ← 前述、説明文参照 | ||||
シフト値 2 | C5 | =C4/SQRT(2) | ||||
シフト値 3 | C6 | =SQRT(2)*C4 |
<データ計算 など> 経度緯度のデータ毎に記述式を複写(行コピー)する。
半球 | 区分 | 記号 | セル |
記 述 式 |
|||||||||||||
北 半 球 (1) |
No. | B10 |
??? ←連番付与 |
||||||||||||||
経度 | C10 | ??? ← 実際の経度データ (1) 0°~180° | |||||||||||||||
緯度 | D10 | ??? ← 実際の緯度データ ※北緯なので 0°~90° | |||||||||||||||
補正 λ-λ0 |
E10 |
=IF($C$2<0,IF(C10-$C$2>180,C10-$C$2-360,C10-$C$2), IF(C10-$C$2<-180,C10+360-$C$2,C10-$C$2)) |
|||||||||||||||
a | F10 |
=ACOS(COS(RADIANS(D10))*SIN(RADIANS(E10))+ COS(RADIANS(E10)))/SQRT(2)) |
|||||||||||||||
b | G10 |
=ACOS(COS(RADIANS(D10))*(SIN(RADIANS(E10))- COS(RADIANS(E10)))/SQRT(2)) |
|||||||||||||||
m | H10 |
=ASIN(SIGN(SIN(RADIANS(E10)))* SQRT(1+COS(F10)*COS(G10)-SIN(F10)*SIN(G10))) |
|||||||||||||||
n | I10 |
=ASIN(-SIGN(COS(RADIANS(E10)))* SQRT(1-COS(F10)*COS(G10)-SIN(F10)*SIN(G10))) |
|||||||||||||||
x | J10 |
=IF(ABS(RADIANS(D10))=PI()/2,0,((1-0.5* (SIN(0))^2)^(-1/2)+4*((1-0.5*(SIN(H10/2))^2)^ (-1/2))+(1-0.5*(SIN(H10))^2)^(-1/2))*H10/6) |
|||||||||||||||
y | K10 |
=IF(ABS(RADIANS(D10))=PI()/2,SIGN(D10)*1.841239, ((1-0.5*(SIN(0))^2)^(-1/2)+4*((1-0.5*(SIN(I10/2))^2)^ (-1/2))+(1-0.5*(SIN(I10))^2)^(-1/2))*I10/6) |
|||||||||||||||
距離(x,y) | L10 | =SQRT(J10^2+K10^2) | |||||||||||||||
θ | M10 | =ATAN(K10/J10)-PI()/4 | |||||||||||||||
① 北半球 |
x①北 | N10 |
=IF(E10=0,0,-SIGN(E10)*IF(M10<PI()/2, -L10*COS(M10),L10*COS(M10))) |
||||||||||||||
y①北 | O10 |
=IF(M10=PI()/2,SIGN(D10)*L10,IF(M10<PI()/2, SIGN(E10)*L10*SIN(M10),-SIGN(E10)*L10*SIN(M10))) |
|||||||||||||||
①シフト 北半球 |
x①s北 | P10 | =N10+$C$6 | ||||||||||||||
y①s北 | Q10 | =O10-$C$6 | |||||||||||||||
④ 北半球 |
x④北 | R10 | =-N10 | ||||||||||||||
y④北 | S10 | =-O10-$C$6 | |||||||||||||||
④シフト 北半球 |
x④s北 | T10 | =R10-$C$6 | ||||||||||||||
y④s北 | U10 | =S10+$C$6 | |||||||||||||||
北 半 球 (2) |
No. | V10 | ??? ←連番付与 | ||||||||||||||
経度 | W10 | ??? ← 実際の経度データ (2) -180°~ 0° | |||||||||||||||
緯度 | X10 | ??? ← 実際の緯度データ ※北緯なので 0°~90° | |||||||||||||||
補正 λ-λ0 |
Y10 |
=IF($C$2<0,IF(W10-$C$2>180,W10-$C$2-360,W10-$C$2), IF(W10-$C$2<-180,W10+360-$C$2,W10-$C$2)) |
|||||||||||||||
a | Z10 |
=ACOS(COS(RADIANS(X10))*(SIN(RADIANS(Y10))+ COS(RADIANS(Y10)))/SQRT(2)) |
|||||||||||||||
b | AA10 |
=ACOS(COS(RADIANS(X10))*(SIN(RADIANS(Y10))- COS(RADIANS(Y10)))/SQRT(2)) |
|||||||||||||||
m | AB10 |
=ASIN(SIGN(SIN(RADIANS(Y10)))*SQRT(1+COS(Z10)* COS(AA10)-SIN(Z10)*SIN(AA10))) |
|||||||||||||||
n | AC10 |
=ASIN(-SIGN(COS(RADIANS(Y10)))*SQRT(1-COS(Z10)* COS(AA10)-SIN(Z10)*SIN(AA10))) |
|||||||||||||||
x | AD10 |
=IF(ABS(RADIANS(X10))=PI()/2,0,((1-0.5*(SIN(0))^ 2)^(-1/2)+4*((1-0.5*(SIN(AB10/2))^2)^(-1/2))+ (1-0.5*(SIN(AB10))^2)^(-1/2))*AB10/6) |
|||||||||||||||
y | AE10 |
=IF(ABS(RADIANS(X10))=PI()/2,SIGN(X10)*1.841239, ((1-0.5*(SIN(0))^2)^(-1/2)+4*((1-0.5*(SIN(AC10/2))^ 2)^(-1/2))+(1-0.5*(SIN(AC10))^2)^(-1/2))*AC10/6) |
|||||||||||||||
距離(x,y) | AF10 | =SQRT(AD10^2+AE10^2) | |||||||||||||||
θ | AG10 | =ATAN(AE10/AD10)-PI()/4 | |||||||||||||||
② 北半球 |
x②北 | AH10 |
=IF(Y10=0,0,-SIGN(Y10)*IF(AG10<PI()/2,-AF10* COS(AG10),AF10*COS(AG10))) |
||||||||||||||
y②北 | AI10 |
=IF(AG10=PI()/2,SIGN(X10)*AF10,IF(AG10<PI()/2, SIGN(Y10)*AF10*SIN(AG10),-SIGN(Y10)*AF10*SIN(AG10))) |
|||||||||||||||
②シフト
北半球 |
x②s北 | AJ10 | =AH10-$C$6 | ||||||||||||||
y②s北 | AK10 | =AI10-$C$6 | |||||||||||||||
③ 北半球 |
x③北 | AL10 | =-AH10 | ||||||||||||||
y③北 | AM10 | =-AI10-$C$6 | |||||||||||||||
③シフト 北半球 |
x③s北 | AN10 | =AL10+$C$6 | ||||||||||||||
y③s北 | AO10 | =AM10+$C$6 | |||||||||||||||
南 半 球 (1) |
No. | AP10 | ??? ←連番付与 | ||||||||||||||
経度 | AQ10 | ??? ← 実際の経度データ (1) 0°~180° | |||||||||||||||
緯度 | AR10 | ??? ← 実際の緯度データ ※南緯なので 0°~ -90° | |||||||||||||||
補正 λ-λ0 |
AS10 |
=IF($C$2<0,IF(AQ10-$C$2>180,AQ10-$C$2-360,AQ10-$C$2), IF(AQ10-$C$2<-180,AQ10+360-$C$2,AQ10-$C$2)) |
|||||||||||||||
a | AT10 |
=ACOS(COS(RADIANS(AR10))*(SIN(RADIANS(AS10))+ COS(RADIANS(AS10)))/SQRT(2)) |
|||||||||||||||
b | AU10 |
=ACOS(COS(RADIANS(AR10))*(SIN(RADIANS(AS10))- COS(RADIANS(AS10)))/SQRT(2)) |
|||||||||||||||
m | AV10 |
=ASIN(SIGN(SIN(RADIANS(AS10)))*SQRT(1+ COS(AT10)*COS(AU10)-SIN(AT10)*SIN(AU10))) |
|||||||||||||||
n | AW10 |
=ASIN(-SIGN(COS(RADIANS(AS10)))*SQRT(1- COS(AT10)*COS(AU10)-SIN(AT10)*SIN(AU10))) |
|||||||||||||||
x | AX10 |
=IF(ABS(RADIANS(AR10))=PI()/2,0,((1-0.5*(SIN(0))^ 2)^(-1/2)+4*((1-0.5*(SIN(AV10/2))^2)^(-1/2))+ (1-0.5*(SIN(AV10))^2)^(-1/2))*AV10/6) |
|||||||||||||||
y | AY10 |
=-IF(ABS(RADIANS(AR10))=PI()/2,SIGN(AR10)*1.841239, ((1-0.5*(SIN(0))^2)^(-1/2)+4*((1-0.5*(SIN(AW10/2))^ 2)^(-1/2))+(1-0.5*(SIN(AW10))^2)^(-1/2))*AW10/6) |
|||||||||||||||
距離(x,y) | AZ10 | =SQRT(AX10^2+AY10^2) | |||||||||||||||
θ | BA10 | =ATAN(AY10/AX10)-PI()/4 | |||||||||||||||
①
南半球 |
x①南 | BB10 |
=IF(AS10=0,0,-SIGN(AS10)*IF(BA10<PI()/2, -AZ10*COS(BA10),AZ10*COS(BA10)))-$C$5 |
||||||||||||||
y①南 | BC10 |
=IF(BA10=PI()/2,SIGN(AR10)*AZ10,IF(BA10<PI()/2, SIGN(AS10)*AZ10*SIN(BA10),SIGN(AS10)* AZ10*SIN(BA10)))-$C$5 |
|||||||||||||||
①シフト
南半球 |
x①s南 | BD10 | =BB10+$C$6 | ||||||||||||||
y①s南 | BE10 | =BC10-$C$6 | |||||||||||||||
④
南半球 |
x④南 | BF10 |
=-IF(AS10=0,0,-SIGN(AS10)*IF(BA10<PI()/2, -AZ10*COS(BA10),AZ10*COS(BA10)))+$C$5 |
||||||||||||||
y④南 | BG10 |
=-IF(BA10=PI()/2,SIGN(AR10)*AZ10,IF(BA10<PI()/2, SIGN(AS10)*AZ10*SIN(BA10),SIGN(AS10)* AZ10*SIN(BA10)))-$C$5 |
|||||||||||||||
④シフト
南半球 |
x④s南 | BH10 | =BF10-$C$6 | ||||||||||||||
y④s南 | BI10 | =BG10+$C$6 | |||||||||||||||
南 半 球 (2) |
No. | BJ10 | ??? ←連番付与 | ||||||||||||||
経度 | BK10 | ??? ← 実際の経度データ (2) -180°~ 0° | |||||||||||||||
緯度 | BL10 | ??? ← 実際の緯度データ ※南緯なので 0°~ -90° | |||||||||||||||
補正 λ-λ0 |
BM10 |
=IF($C$2<0,IF(BK10-$C$2>180,BK10-$C$2-360,BK10-$C$2), IF(BK10-$C$2<-180,BK10+360-$C$2,BK10-$C$2)) |
|||||||||||||||
a | BN10 |
=ACOS(COS(RADIANS(BL10))*(SIN(RADIANS(BM10))+ COS(RADIANS(BM10)))/SQRT(2)) |
|||||||||||||||
b | BO10 |
=ACOS(COS(RADIANS(BL10))*(SIN(RADIANS(BM10))- COS(RADIANS(BM10)))/SQRT(2)) |
|||||||||||||||
m | BP10 |
=ASIN(SIGN(SIN(RADIANS(BM10)))*SQRT(1+ COS(BN10)*COS(BO10)-SIN(BN10)*SIN(BO10))) |
|||||||||||||||
n | BQ10 |
=ASIN(-SIGN(COS(RADIANS(BM10)))*SQRT(1- COS(BN10)*COS(BO10)-SIN(BN10)*SIN(BO10))) |
|||||||||||||||
x | BR10 |
=IF(ABS(RADIANS(BL10))=PI()/2,0,((1-0.5*(SIN(0))^ 2)^(-1/2)+4*((1-0.5*(SIN(BP10/2))^2)^(-1/2))+ (1-0.5*(SIN(BP10))^2)^(-1/2))*BP10/6) |
|||||||||||||||
y | BS10 |
=-IF(ABS(RADIANS(BL10))=PI()/2,SIGN(BL10)*1.841239, ((1-0.5*(SIN(0))^2)^(-1/2)+4*((1-0.5*(SIN(BQ10/2))^ 2)^(-1/2))+(1-0.5*(SIN(BQ10))^2)^(-1/2))*BQ10/6) |
|||||||||||||||
距離(x,y) | BT10 | =SQRT(BR10^2+BS10^2) | |||||||||||||||
θ | BU10 | =ATAN(BS10/BR10)-PI()/4 | |||||||||||||||
②
南半球 |
x②南 | BV10 |
=IF(BM10=0,0,-SIGN(BM10)*IF(BU10<PI()/2,- BT10*COS(BU10),BT10*COS(BU10)))-$C$5 |
||||||||||||||
y②南 | BW10 |
=IF(BU10=PI()/2,SIGN(BL10)*BT10,IF(BU10<PI()/2, SIGN(BM10)*BT10*SIN(BU10),-SIGN(BM10)* BT10*SIN(BU10)))-$C$5 |
|||||||||||||||
②シフト
南半球 |
x②s南 | BX10 | =BV10+$C$6 | ||||||||||||||
y②s南 | BY10 | =BW10+$C$6 | |||||||||||||||
③
南半球 |
x③南 | BZ10 |
=-IF(BM10=0,0,-SIGN(BM10)*IF(BU10<PI()/2, -BT10*COS(BU10),BT10*COS(BU10)))+$C$5 |
||||||||||||||
y③南 | CA10 |
=-IF(BU10=PI()/2,SIGN(BL10)*BT10,IF(BU10<PI()/2, SIGN(BM10)*BT10*SIN(BU10),-SIGN(BM10)*BT10* SIN(BU10)))-$C$5 |
|||||||||||||||
③シフト
南半球 |
x③s南 | CB10 | =BZ10-$C$6 | ||||||||||||||
y③s南 | CC10 | =CA10-$C$6 |
[図 6-7-2-5-②-2] Peirce Quincuncial 図法 ( Peirce Quincuncial Projection ) 赤道◇
【地図主点(中心)】東経 180゚、緯度 0゚ 【経度間隔】15゚ 【緯度間隔】10゚
【備考】・投影式の積分は、シンプソンの公式を利用した簡易積分を実施。
・平面充填用のタイル(正方形)として用いる。
・赤道は、タイル外周に対しひし形(◇)。
・南北回帰線、南北極圏、日付変更線は省略した。
この平面充填タイルをシフトして上下左右に並べると
6-7-2-6 Adams World in a Square I
【 投影式 】sin φ' = tan (φ/2)
cos a = {cos φ' sin [(λ - λ0)/2] - sin φ'} / 21/2
cos b = {cos φ' sin [(λ - λ0)/2] + sin φ'} / 21/2
sin m = ± (1 + cos a cos b - sin a sin b )1/2
↑符号は ( λ - λ0)
sin n = ± (1 - cos a cos b - sin a sin b )1/2
↑符号は φ
x = R ∫0m(1 - 0.5 sin2m)-1/2dm
y = R ∫0n(1 - 0.5 sin2n)-1/2dn
もし |φ| = π/2
x = 0
y = ± 1.841239209 R ←符号はφ
【経度・緯度】 経線:曲線 、緯線:曲線
【 ポイント 】・投影式の中に積分が含まれていますが、シンプソンの
公式を利用して簡易積分をして見ました。
・簡易積分のせいか、補助線などでエラーなるポイント
が発生します。端っこの経線などで起こる可能性があ
りました。そのポイントは、経度か緯度を微調整して
ください。
<例>
緯度
66° ←エラー発生
66.000001°←エラー回避
・描画四角形の四隅が直角にならない場合は、補助線の間
に四隅になる点を追加します。
<例>地図中心が東経135°緯度0度の例です。
描画してみて四隅がだれてしまう箇所が
緯度±70°~72°にあるので、そこに
一行挿入して計算値の列だけに x , y
を追加します。
<四隅の挿入数値>
x y
左上隅 -1.841239209 1.841239209
左下隅 -1.841239209 -1.841239209
右上隅 +1.841239209 1.841239209
左上隅 +1.841239209 -1.841239209
<基準経度・標準緯度・予備計算・共通数値 など> | ||||||||||||||||||||||||||||||||||||
記号 | セルNo. | 記述式 | ||||||||||||||||||||||||||||||||||
λ0 | C2 | ??? ← 中心経度(希望経度を入力) | ||||||||||||||||||||||||||||||||||
R | C3 | 1 | ||||||||||||||||||||||||||||||||||
<データ計算 など> 経度緯度のデータ毎に記述式を複写(行コピー)する。 | ||||||||||||||||||||||||||||||||||||
記号 | セルNo. | 記述式 | ||||||||||||||||||||||||||||||||||
No. | B9 | ??? ← 式を複写する時に、一旦ソートしたり、解析時に役立つので連番号を付与 | ||||||||||||||||||||||||||||||||||
経度 | C9 | ??? ← 実際の経度データ | ||||||||||||||||||||||||||||||||||
緯度 | D9 | ??? ← 実際の緯度データ | ||||||||||||||||||||||||||||||||||
補正 λ-λ0 |
E9 |
=IF($C$2<0,IF(C9-$C$2>180,C9-$C$2-360,C9-$C$2), IF(C9-$C$2<-180,C9+360-$C$2,C9-$C$2)) |
||||||||||||||||||||||||||||||||||
φ' | F9 | =ASIN(TAN(RADIANS(D9/2))) | ||||||||||||||||||||||||||||||||||
a | G9 | =ACOS((COS(F9)*SIN(RADIANS(E9/2))-SIN(F9))/SQRT(2)) | ||||||||||||||||||||||||||||||||||
b | H9 | =ACOS((COS(F9)*SIN(RADIANS(E9/2))+SIN(F9))/SQRT(2)) | ||||||||||||||||||||||||||||||||||
m | I9 | =ASIN(SIGN(E9)*SQRT(1+COS(G9)*COS(H9)-SIN(G9)*SIN(H9))) | ||||||||||||||||||||||||||||||||||
n | J9 | =ASIN(SIGN(D9)*SQRT(1-COS(G9)*COS(H9)-SIN(G9)*SIN(H9))) | ||||||||||||||||||||||||||||||||||
x | K9 |
=IF(ABS(RADIANS(D9))=PI()/2,0,((1-0.5*(SIN(0))^2)^(-1/2)+ 4*((1-0.5*(SIN(I9/2))^2)^(-1/2))+(1-0.5*(SIN(I9))^2)^(-1/2))*I9/6) |
||||||||||||||||||||||||||||||||||
y | L9 |
=IF(ABS(RADIANS(D9))=PI()/2,IF(D9<0,-1.85407,1.85407), ((1-0.5*(SIN(0))^2)^(-1/2)+4*((1-0.5*(SIN(J9/2))^2)^(-1/2))+ (1-0.5*(SIN(J9))^2)^(-1/2))*J9/6) |
||||||||||||||||||||||||||||||||||
端CH | M10 |
=IF(K10="",0,IF(AND(ABS(K10)>0.2,K9*K10<0),"●", IF(AND(K9<>"",K10>PI()/2,ABS(K9-K10)>0.2),"●",0))) |
||||||||||||||||||||||||||||||||||
[図 6-7-2-6] Adams World in a Square I 図法 ( Adams World in a Square I Projection )
【地図主点(中心)】東経 135゚、緯度 0゚ 【経度間隔】15゚ 【緯度間隔】10゚
【備考】投影式の積分は、シンプソンの公式を利用した簡易積分を実施
6-7-2-7 Adams World in a Square Ⅱ
【 投影式 】cos a = cos φ' sin [(λ - λ0)/2]
cos b = sin φ'
sin φ' = tan (φ/2)
sin m = ± (1 + cos a cos b - sin a sin b )1/2
↑符号は (sinφ'+cos α)
sin n = ± (1 - cos a cos b - sin a sin b )1/2
↑符号は (sinφ'-cos α)
x = R ∫0m(1 - 0.5 sin2m)-1/2dm
y = R ∫0n(1 - 0.5 sin2n)-1/2dn
もし |φ| = π/2
x & y = ± 1.841239209 R ←符号はφ
【経度・緯度】 経線:曲線 、緯線:曲線
【 ポイント 】・全球投影の正方形となるが、中心経度が45°傾いている。
ここでは、全球描画をしたものと45°回転させたひし形
にしたものを描画してみる。
・投影式の中に積分が含まれていますが、シンプソンの公式
を利用して簡易積分をして見ました。
・簡易積分のせいか、補助線などでエラーなるポイントが
発生します。端っこの経線などで起こる可能性がありまし
た。そのポイントは、経度か緯度を微調整してください。
<例>
緯度
56° ←エラー発生
56.000001°←エラー回避
<基準経度・標準緯度・予備計算・共通数値 など> | ||||||||||||||||||||||||||||||||||||
記号 | セルNo. | 記述式 | ||||||||||||||||||||||||||||||||||
λ0 | C2 | ??? ← 中心経度(希望経度を入力) | ||||||||||||||||||||||||||||||||||
R | C3 | 1 | ||||||||||||||||||||||||||||||||||
<データ計算 など> 経度緯度のデータ毎に記述式を複写(行コピー)する。 | ||||||||||||||||||||||||||||||||||||
記号 | セルNo. | 記述式 | ||||||||||||||||||||||||||||||||||
No. | B9 | ??? ← 式を複写する時に、一旦ソートしたり、解析時に役立つので連番号を付与 | ||||||||||||||||||||||||||||||||||
経度 | C9 | ??? ← 実際の経度データ | ||||||||||||||||||||||||||||||||||
緯度 | D9 | ??? ← 実際の緯度データ | ||||||||||||||||||||||||||||||||||
補正 λ-λ0 |
E9 |
=IF($C$2<0,IF(C9-$C$2>180,C9-$C$2-360,C9-$C$2), IF(C9-$C$2<-180,C9+360-$C$2,C9-$C$2)) |
||||||||||||||||||||||||||||||||||
φ' | F9 | =ASIN(TAN(RADIANS(D9/2))) | ||||||||||||||||||||||||||||||||||
a | G9 | =ACOS(COS(F9)*SIN(RADIANS(E9/2))) | ||||||||||||||||||||||||||||||||||
b | H9 | =ACOS(SIN(F9)) | ||||||||||||||||||||||||||||||||||
m | I9 | =ASIN(SIGN(SIN(F9)+COS(G9))*SQRT(1+COS(G9)*COS(H9)-SIN(G9)*SIN(H9))) | ||||||||||||||||||||||||||||||||||
n | J9 | =ASIN(SIGN(SIN(F9)-COS(G9))*SQRT(1-COS(G9)*COS(H9)-SIN(G9)*SIN(H9))) | ||||||||||||||||||||||||||||||||||
x | K9 |
=IF(ABS(RADIANS(D9))=PI()/2,SIGN(D9)*1.841239209, ((1-0.5*(SIN(0))^2)^(-1/2)+4*((1-0.5*(SIN(I9/2))^2)^(-1/2))+ (1-0.5*(SIN(I9))^2)^(-1/2))*I9/6) |
||||||||||||||||||||||||||||||||||
y | L9 |
=IF(ABS(RADIANS(D9))=PI()/2,SIGN(D9)*1.841239209, ((1-0.5*(SIN(0))^2)^(-1/2)+4*((1-0.5*(SIN(J9/2))^2)^(-1/2))+ (1-0.5*(SIN(J9))^2)^(-1/2))*J9/6) |
||||||||||||||||||||||||||||||||||
端CH | M10 |
=IF(K10="",0,IF(AND(ABS(K10)>0.2,K9*K10<0),"●", IF(AND(K9<>"",K10>PI()/2,ABS(K9-K10)>0.2),"●",0))) |
||||||||||||||||||||||||||||||||||
[図 6-7-2-7] Adams World in a Square II 図法
( Adams World in a Square II Projection )
【地図主点(中心)】東経 135゚、緯度 0゚ 【経度間隔】15゚ 【緯度間隔】10゚
【備考】投影式の積分は、シンプソンの公式を利用した簡易積分を実施
上図を左に45°傾けてひし形表示とするには、6-7-2-4のひし形を参考にしてください。
<基準経度・標準緯度・予備計算・共通数値 など> | ||||||||||||||||||||||||||||||||||||
記号 | セルNo. | 記述式 | ||||||||||||||||||||||||||||||||||
λ0 | C2 | ??? ← 中心経度(希望経度を入力) | ||||||||||||||||||||||||||||||||||
R | C3 | 1 | ||||||||||||||||||||||||||||||||||
<データ計算 など> 経度緯度のデータ毎に記述式を複写(行コピー)する。 | ||||||||||||||||||||||||||||||||||||
記号 | セルNo. | 記述式 | ||||||||||||||||||||||||||||||||||
No. | B9 | ??? ← 式の複写時、一旦ソートしたり,解析時に役立つので連番号を付与 | ||||||||||||||||||||||||||||||||||
経度 | C9 | ??? ← 実際の経度データ | ||||||||||||||||||||||||||||||||||
緯度 | D9 | ??? ← 実際の緯度データ | ||||||||||||||||||||||||||||||||||
補正 λ-λ0 |
E9 |
=IF($C$2<0,IF(C9-$C$2>180,C9-$C$2-360,C9-$C$2), IF(C9-$C$2<-180,C9+360-$C$2,C9-$C$2)) |
||||||||||||||||||||||||||||||||||
φ' | F9 | =ASIN(TAN(RADIANS(D9/2))) | ||||||||||||||||||||||||||||||||||
a | G9 | =ACOS(COS(F9)*SIN(RADIANS(E9/2))) | ||||||||||||||||||||||||||||||||||
b | H9 | =ACOS(SIN(F9)) | ||||||||||||||||||||||||||||||||||
m | I9 | =ASIN(SIGN(SIN(F9)+COS(G9))*SQRT(1+COS(G9)*COS(H9)-SIN(G9)*SIN(H9))) | ||||||||||||||||||||||||||||||||||
n | J9 | =ASIN(SIGN(SIN(F9)-COS(G9))*SQRT(1-COS(G9)*COS(H9)-SIN(G9)*SIN(H9))) | ||||||||||||||||||||||||||||||||||
x (回転前) |
K9 |
=IF(ABS(RADIANS(D9))=PI()/2,SIGN(D9)*1.841239209, ((1-0.5*(SIN(0))^2)^(-1/2)+4*((1-0.5*(SIN(I9/2))^2)^(-1/2))+ (1-0.5*(SIN(I9))^2)^(-1/2))*I9/6) |
||||||||||||||||||||||||||||||||||
y (回転前) |
L9 |
=IF(ABS(RADIANS(D9))=PI()/2,SIGN(D9)*1.841239209, ((1-0.5*(SIN(0))^2)^(-1/2)+4*((1-0.5*(SIN(J9/2))^2)^(-1/2))+ (1-0.5*(SIN(J9))^2)^(-1/2))*J9/6) |
||||||||||||||||||||||||||||||||||
距離 | M9 | =SQRT(K9^2+L9^2) | ||||||||||||||||||||||||||||||||||
θ | N9 | =ATAN(L9/K9)+PI()/4 | ||||||||||||||||||||||||||||||||||
xr | O9 | =IF(E9=0,0,-SIGN(E9)*IF(N9<PI()/2,-M9*COS(N9),M9*COS(N9))) | ||||||||||||||||||||||||||||||||||
yr | P9 |
=IF(N9=PI()/2,SIGN(D9)*M9,IF(N9<PI()/2,SIGN(E9)* M9*SIN(N9),-SIGN(E9)*M9*SIN(N9))) |
||||||||||||||||||||||||||||||||||
端CH | Q10 |
=IF(K10="",0,IF(AND(ABS(K10)>0.2,K9*K10<0),"●", IF(AND(K9<>"",K10>PI()/2,ABS(K9-K10)>0.2),"●",0))) |
||||||||||||||||||||||||||||||||||
[図 6-7-2-7] Adams World in a Square II 図法
( Adams World in a Square II Projection )
【地図主点(中心)】東経 135゚、緯度 0゚ 【経度間隔】15゚ 【緯度間隔】10゚
【備考】投影式の積分は、シンプソンの公式を利用した簡易積分を実施。
参考文献の投影式を用いて描画すると45°傾いた四角になるため、
45°左に回転させる式を考えて描画することにより◆を実現した。
あなたもジンドゥーで無料ホームページを。 無料新規登録は https://jp.jimdo.com から