6-5-2 非投射方位図法

 

   6-5-2-1 Azimuthal Equidistant (正距方位図法)

         【 投影式 】cos c = sinφ1 sinφ + cosφ1 cosφ cos (λ-λ0)

 k'= c / sin c

 x = k' cosφ sin (λ-λ0)

 y = k' [ cosφ1 sinφ - sinφ1 cosφ cos (λ-λ0) ]

         【経度・緯度】 経線:曲線 、緯線:曲線

                【 ポイント 】全球のデータを用いて計算する。

  <基準経度・標準緯度・予備計算・共通数値 など>                
     記号  セルNo.         記述式                
      λ0     C2    ???  ← 中心経度(希望経度を入力)                
       R     C3       1  ← 描画係数                
                                                                         
  <外周計算>
     記号  セルNo.         記述式                
     経度     E3   180                
     緯度     F3      0                
       x      G3   =SIN(RADIANS(F3))*SIN(RADIANS(F3))+COS(RADIANS(F3))*
          COS(RADIANS(F3))*COS(RADIANS(E3))  ← φ1=0 で計算
               
                 
       c     H3   =ACOS(G3)                
      K'      I3   =H3/SIN(H3)                
       x      J3   =I3*COS(RADIANS(F3))*SIN(RADIANS(E3))
           ↑この値が
描画半径
となる      計算値は π = 3.14 となる 
               
                 
                                                                         
  <データ計算 など>  経度緯度のデータ毎に記述式を複写(行コピー)する。
     記号  セルNo.         記述式
      No.     B9   ???  ← 式を複写する時に、一旦ソートしたり、解析時に役立つので連番号を付与
     経度     C9   ???  ← 実際の経度データ
     緯度     D9   ???  ← 実際の緯度データ
     補正
  λ-λ
0
    E9  =IF($C$2<0,IF(C9-$C$2>180,C9-$C$2-360,C9-$C$2),
                                    IF(C9-$C$2<-180,C9+360-$C$2,C9-$C$2))
 
     cos z      F9   =SIN(RADIANS($C$3))*SIN(RADIANS(D9))+COS(RADIANS($C$3))*
                                           COS(RADIANS(D9))*COS(RADIANS(E9))
 
       C      G9   =ACOS(F9)
       K'      H9   =G9/SIN(G9)
       x      I9   =H9*COS(RADIANS(D9))*SIN(RADIANS(E9))
       y      J9   =H9*(COS(RADIANS($C$3))*SIN(RADIANS(D9))-SIN(RADIANS($C$3))*
                                             COS(RADIANS(D9))*COS(RADIANS(E9)))
 

 

 <描画範囲に外周を付ける> 描画範囲を特定する。

  5-2-3 外周を参照し『r』は、セルJ3 を指定する。

[6-5-2-1] 正距方位図法 ( Azimuthal Equidistant Projection )

【地図主点(中心)】東経 135゚、北緯35゚ 【経度間隔】15゚【緯度間隔】10

ダウンロード
6-5-2-1_Azimuthal Equidistant.pdf
PDFファイル 350.1 KB

   6-5-2-2 Lambert Azimuthal Equal-Area (ランベルト正積方位図法)

 

    6-5-2-2-1 極面

         【 投影式 】ρ = 2R sin ( π / 4 – φ / 2 )

 x = ρ sin (λ - λ0)

 y = - ρ cos (λ - λ0)

         【経度・緯度】  経線:直線 、緯線:曲線

                【 ポイント 】全球のデータを用いて計算する。

  <基準経度・標準緯度・予備計算・共通数値 など>                
     記号  セルNo.         記述式                
      λ0     C2    ???  ← 中心経度(希望経度を入力)                
       R     C3       1  ← 描画係数                
                                                                         
  <データ計算 など>  経度緯度のデータ毎に記述式を複写(行コピー)する。
     記号  セルNo.         記述式
      No.     B9   ???  ← 式を複写する時に、一旦ソートしたり、解析時に役立つので連番号を付与
     経度     C9   ???  ← 実際の経度データ
     緯度     D9   ???  ← 実際の緯度データ
     補正
  λ-λ
0
    E9  =IF($C$2<0,IF(C9-$C$2>180,C9-$C$2-360,C9-$C$2),
                                    IF(C9-$C$2<-180,C9+360-$C$2,C9-$C$2))
 
      ρ     F9   =2*SIN(PI()/4-RADIANS(D9)/2)
       x      G9   =F9*SIN(RADIANS(E9))
       y      H9   =-F9*COS(RADIANS(E9))

 

[6-5-2-2-1] ランベルト正積方位図法 - 極面 

                             ( Lambert Polar Azimuthal Equal-area Projection,Polar Aspect )

【地図主点(中心)】東経 135゚、緯度90゚ 【経度間隔】15゚【緯度間隔】10

ダウンロード
6-5-2-2-1_Lambert Azimuthal 正積_北極面.pdf
PDFファイル 333.2 KB

    6-5-2-2-2 赤道面

        【 投影式 】cos z = cos φcos ( λ - λ0)

K = [ 2 / ( 1 + cos z )]1/2

 x = R K cosφ sin ( λ - λ0)

 y = R K sinφ

 もし cos z = - 1 , 半径 = 2R

         【経度・緯度】  経線:曲線 、緯線:曲線

                【 ポイント 】全球のデータを用いて計算する。

  <基準経度・標準緯度・予備計算・共通数値 など>                
     記号  セルNo.         記述式                
      λ0     C2    ???  ← 中心経度(希望経度を入力)                
       R     C3       1  ← 描画係数                
                                                                         
  <データ計算 など>  経度緯度のデータ毎に記述式を複写(行コピー)する。
     記号  セルNo.         記述式
      No.     B9   ???  ← 式を複写する時に、一旦ソートしたり、解析時に役立つので連番号を付与
     経度     C9   ???  ← 実際の経度データ
     緯度     D9   ???  ← 実際の緯度データ
     補正
  λ-λ
0
    E9  =IF($C$2<0,IF(C9-$C$2>180,C9-$C$2-360,C9-$C$2),
                                    IF(C9-$C$2<-180,C9+360-$C$2,C9-$C$2))
 
      K     F9   =SQRT(2/(1+COS(RADIANS(D9))*COS(RADIANS(E9))))
       x      G9   =F9*COS(RADIANS(D9))*SIN(RADIANS(E9))
       y      H9   =-F9*SIN(RADIANS(D9))

 

 <描画範囲に外周を付ける> 描画範囲を特定する。

  5-2-3 外周を参照し『r』は、R 1にしているので『2』を指定する。

[6-5-2-2-2] ランベルト正積方位図法 - 赤道面

                    ( Lambert Equatorial Azimuthal Equal-area Projection,Equatorial Aspect )

【地図主点(中心)】東経 135゚、緯度 0゚ 【経度間隔】15゚【緯度間隔】10

ダウンロード
6-5-2-2-2_Lambert Azimuthal 正積_赤道面.pdf
PDFファイル 351.4 KB

    6-5-2-2-3 傾斜面

         【 投影式 】cos z = sinφ1 sinφ + cosφ1 cosφ cos (λ - λ0)

 K = [ 2 / ( 1 + cos z ) ]1/2

 x = R K cosφ sin(λ - λ0)

 y = R K [ cosφ1 sinφ - sinφ1 cosφ cos(λ - λo)]

 もし cos z = - 1 , 描画外周半径 = 2R

 ※この式のφ1をゼロにすると赤道面、φ190

                     すると極面の描画に利用できます。

         【経度・緯度】  経線:曲線 、緯線:曲線

                【 ポイント 】全球のデータを用いて計算する。

  <基準経度・標準緯度・予備計算・共通数値 など>                
     記号  セルNo.         記述式                
      λ0     C2    ???  ← 中心経度(希望経度を入力)                
      φ1     C3     ??    中心緯度(希望緯度を入力)                
       R     C4      1                
                                                                         
  <データ計算 など>  経度緯度のデータ毎に記述式を複写(行コピー)する。
     記号  セルNo.         記述式
      No.     B9   ???  ← 式を複写する時に、一旦ソートしたり、解析時に役立つので連番号を付与
     経度     C9   ???  ← 実際の経度データ
     緯度     D9   ???  ← 実際の緯度データ
     補正
  λ-λ
0
    E9  =IF($C$2<0,IF(C9-$C$2>180,C9-$C$2-360,C9-$C$2),
                                    IF(C9-$C$2<-180,C9+360-$C$2,C9-$C$2))
 
      K     F9   =SQRT(2/(1+SIN(RADIANS($C$3))*SIN(RADIANS(D9))+
                 COS(RADIANS($C$3))*COS(RADIANS(D9))*COS(RADIANS(E9))))
 
       x      G9   =F9*COS(RADIANS(D9))*SIN(RADIANS(E9))
       y      H9   =F9*(COS(RADIANS($C$3))*SIN(RADIANS(D9))-
                   SIN(RADIANS($C$3))*COS(RADIANS(D9))*COS(RADIANS(E9)))
 

 

 <描画範囲に外周を付ける> 描画範囲を特定する。

  5-2-3 外周を参照し『r』は、R 1にしているので『2』を指定する。

[6-5-2-2-3] ランベルト正積方位図法 - 傾斜面

                      ( Lambert Azimuthal Equal-area Projection,Oblique Aspect )

【地図主点(中心)】東経 135゚、北緯35゚ 【経度間隔】15゚【緯度間隔】10

ダウンロード
6-5-2-2-3_Lambert Azimuthal 正積_傾斜面.pdf
PDFファイル 365.3 KB

   6-5-2-3 Airy

 

    6-5-2-3-1 極面

         【 投影式 】β = π / 2 - φb

 z = π / 2 - φ

 ρ = 2R [ cot ( z / 2) In sec ( z /2 ) +

                       tan ( z / 2 ) cot2 ( β / 2 ) In sec ( β / 2 ) ]

  もし  z = 0 ,  ρ = 0

 x = ρ sin( λ - λ0 )

 y = - ρ cos( λ - λ0 )

         【経度・緯度】   経線:直線 、緯線:曲線

 【 ポイント 】・中心から離れるにつれ歪が増大しますが、

 φb(境界緯度)によって歪み方も変化する。

 北極を中心としてφbの変化により経線緯線

                        の変化を比較して見ると下図のようである。

            (各φbのスケールは、比較のため合わせている)

            φbの変化により、描画スケールも変化しますが描画の

            形状自体はほとんど変化しません。

                        参考文献などでは中心から90°程度を描画するものが

  多いが、ここでは、φb40°とし中心から90°以上

  離れた部分も描画して見た。

 

  <基準経度・標準緯度・予備計算・共通数値 など>                
     記号  セルNo.         記述式                
      λ0     C2    ???  ← 中心経度(希望経度を入力)                
      φb     C3     ??      境界緯度(ここでは 40°を入力して描画して見た)                
       R     C4      1                
    β/ 2      C5  =(PI()/2-RADIANS(C3))/2                
                                                                         
  <データ計算 など>  経度緯度のデータ毎に記述式を複写(行コピー)する。
     記号  セルNo.         記述式
      No.     B9   ???  ← 式を複写する時に、一旦ソートしたり、解析時に役立つので連番号を付与
     経度     C9   ???  ← 実際の経度データ
     緯度     D9   ???  ← 実際の緯度データ
     補正
  λ-λ
0
    E9  =IF($C$2<0,IF(C9-$C$2>180,C9-$C$2-360,C9-$C$2),
                                    IF(C9-$C$2<-180,C9+360-$C$2,C9-$C$2))
 
       z      F9   =PI()/2-RADIANS(D9)
      ρ      G9   =IF(F9=0,0,2*(COT(F9/2)*LN(1/COS(F9/2))+TAN(F9/2)*
                                             (COT($C$5))^2*LN(1/COS($C$5))))
 
       x      G9   =G9*SIN(RADIANS(E9))
       y      H9   =-G9*COS(RADIANS(E9))

 

 [6-5-2-3-1] Airy 図法 - 極面 ( Airy Projection,Polar Aspect )

              【地図主点(中心)】東経 135゚、北緯90゚ 【主描画範囲】赤道以北(海岸線色:緑)

                     【境界緯度】φb40°【経度間隔】15゚【緯度間隔】10

 

ダウンロード
6-5-2-3-1_Airy_北極面.pdf
PDFファイル 787.9 KB

 [6-5-2-3-1] Airy 図法 - 極面 - 半球縦列 ( Airy Projection,Polar Aspect )

               【地図主点(中心)】北半球:東経 135゚、北緯90゚ 南半球:東経135゚、南緯90

                   【境界緯度】φb40°【経度間隔】15゚【緯度間隔】10

ダウンロード
6-5-2-3-1_Airy_北極面_半球縦列.pdf
PDFファイル 347.9 KB

    6-5-2-3-2 赤道面

        【 投影式 】 β = π / 2 - φb

z = π / 2 – φ

 cos z = cosφcos( λ - λ0 )

 K = - R{ [ ln (1/2 + cos z /2)] / (1 - cos z) +

 2 [1n cos(β/2)] / [ tan2( β / 2 ) (1 + cos z ) ]  }

 もし  z = 0, K = R { 0.5 - [ ln cos ( β / 2) ] / tan2( β / 2 )}

 x = RK cosφsin ( λ - λ0 )

 y = RK sinφ

         【経度・緯度】  経線:曲線 、緯線:曲線

        【 ポイント 】中心から離れるにつれ歪が増大しますが、
                        φb(境界緯度)によって歪み方も変化する。
                        赤道を中心としてφbの変化により経線緯線
                        の変化を比較して見ると下図のようである。

                       (各φbのスケールは、比較のため合わせている)

            φbの変化により、描画スケールも変化しますが

            描画の形状自体はほとんど変化しません。

                        参考文献などでは中心から90°程度を描画する

  ものが多いが、ここでは、φb85°とし中心から

  90°以上離れた部分も描画して見た。

 

  <基準経度・標準緯度・予備計算・共通数値 など>                
     記号  セルNo.         記述式                
      λ0     C2    ???  ← 中心経度(希望経度を入力)                
      φb     C3     ??      境界緯度                
       R     C4      1                
    β/ 2      C5  =(PI()/2-RADIANS(C3))/2                
                                                                         
  <データ計算 など>  経度緯度のデータ毎に記述式を複写(行コピー)する。
     記号  セルNo.         記述式
      No.     B9   ???  ← 式を複写する時に、一旦ソートしたり、解析時に役立つので連番号を付与
     経度     C9   ???  ← 実際の経度データ
     緯度     D9   ???  ← 実際の緯度データ
     補正
  λ-λ
0
    E9  =IF($C$2<0,IF(C9-$C$2>180,C9-$C$2-360,C9-$C$2),
                                    IF(C9-$C$2<-180,C9+360-$C$2,C9-$C$2))
 
    cos z      F9   =COS(RADIANS(D9))*COS(RADIANS(E9))
      K      G9   =IF(F9=1,(0.5-(LN(COS($C$5)))/(TAN($C$5))^2),
          -((LN(1/2+F9/2))/(1-F9)+2*(LN(COS($C$5)))/((TAN($C$5))^2*(1+F9))))
 
       x      G9   =G9*COS(RADIANS(D9))*SIN(RADIANS(E9))
       y      H9   =G9*SIN(RADIANS(D9))

 

[6-5-2-3-2] Airy 図法 - 赤道面 ( Airy Projection,Equatorial Aspect )

           【地図主点(中心)】東経 135゚、緯度 0゚ 【主描画範囲】地図主点を中心とした90

                  【境界緯度】φb40°【経度間隔】15゚【緯度間隔】10

ダウンロード
6-5-2-3-2_Airy_赤道面.pdf
PDFファイル 419.6 KB

[6-5-2-3-2] Airy 図法 - 赤道面、半球並列 ( Airy Projection,Equatorial Aspect ) 

                               【地図主点(中心)】左:東経 135゚、緯度 0゚ 右:西経45゚、緯度 0

                               【主描画範囲】左右の地図主点を中心とした90

                                                    【経度間隔】15゚【緯度間隔】10

ダウンロード
6-5-2-3-2_Airy_赤道面_半球並列.pdf
PDFファイル 353.7 KB

    6-5-2-3-3 傾斜面

        【 投影式 】 β = π / 2 - φb

 z = π / 2 - φ

 cos z = sinφ1 sinφ+cosφ1cosφcos( λ - λ0 )

 K = - R{ [ ln (1/2 + cos z/2)] / (1 - cos z) +

                      2 [1n cos (β /2)] / [ tan2(β /2) (1 + cos z)]}

 もし  z = 0, K =R{0.5-[ln cos (β /2)]/tan2(β /2)}

 x = RK cosφsin ( λ - λ0 )

 y = RK [cosφ1 sinφ- sinφ1 cosφcos( λ - λ0)]

         【経度・緯度】  経線:曲線 、緯線:曲線

                【 ポイント 】・中心から離れるにつれ歪が増大しますが、
                        φb(境界緯度)によって歪み方も変化する。
                        赤道を中心としてφbの変化により経線緯線
                        の変化を比較して見ると下図のようである。

                         ( 中心点:東経135°北緯35°)

            φbの変化により、描画スケールも変化しますが

            描画の形状自体はほとんど変化しません。

                        参考文献などでは中心から90°程度を描画する

  ものが多いが、ここでは、φb20°とし中心から

  90°以上離れた部分も描画して見た。

 

  <基準経度・標準緯度・予備計算・共通数値 など>                
     記号  セルNo.         記述式                
    λ0     C2    ???  ← 中心経度(希望経度を入力)                
    φb     C3     ??      境界緯度(ここでは 20°を入力して描画して見た)                
    φ1     C4     ??      中心緯度                
     R     C5      1                
   β/ 2      C6  =(PI()/2-RADIANS(C3))/2                
                                                                         
  <描画範囲の半径計算> ここでは、中心から 90° 離れたところまで描画することを想定している。
     記号  セルNo.         記述式
   経度      E3   =IF(C2+90>180,C2+90-360,C2+90)
   緯度      F3     0
   補正
 λ-λ
0 
    G3  =IF($C$2<0,IF(E3-$C$2>180,E3-$C$2-360,E3-$C$2),
                                         IF(E3-$C$2<-180,E3+360-$C$2,E3-$C$2))
 
  os z      H3  =SIN(RADIANS($C$4))*SIN(RADIANS(F3))+
                 COS(RADIANS($C$4))*COS(RADIANS(F3))*COS(RADIANS(G3))
 
   K      I3   =IF(H3=1,(0.5-(LN(COS($C$6)))/(TAN($C$6))^2),
          -((LN(1/2+H3/2))/(1-H3)+2*(LN(COS($C$6)))/((TAN($C$6))^2*(1+H3))))
 
     x      J3   =I3*COS(RADIANS(F3))*SIN(RADIANS(G3))   ← この値が描画半径である。
                                                                         
  <データ計算 など>  経度緯度のデータ毎に記述式を複写(行コピー)する。
     記号  セルNo.         記述式
      No.     B9   ???  ← 式を複写する時に、一旦ソートしたり、解析時に役立つので連番号を付与
   経度     C9   ???  ← 実際の経度データ
   緯度     D9   ???  ← 実際の緯度データ
   補正
 λ-λ
0
    E9  =IF($C$2<0,IF(C9-$C$2>180,C9-$C$2-360,C9-$C$2),
                                    IF(C9-$C$2<-180,C9+360-$C$2,C9-$C$2))
 
    cos z      F9 

 =SIN(RADIANS($C$4))*SIN(RADIANS(D9))+COS(RADIANS($C$4))*

                                        COS(RADIANS(D9))*COS(RADIANS(E9))

 
      K      G9   =IF(F9=1,(0.5-(LN(COS($C$6)))/(TAN($C$6))^2),-((LN(1/2+F9/2))/
                            (1-F9)+2*(LN(COS($C$6)))/((TAN($C$6))^2*(1+F9))))
 
       x      H9   =G9*COS(RADIANS(D9))*SIN(RADIANS(E9))
       y      I9   =G9*(COS(RADIANS($C$4))*SIN(RADIANS(D9))-
            SIN(RADIANS($C$4))*COS(RADIANS(D9))*COS(RADIANS(E9)))
 
 

 描画

 範囲

    J9  =IF(H9^2+I9^2>=$J$3^2,"●",0) 

 

[6-5-2-3-3] Airy 図法 - 傾斜面 ( Airy Projection,Oblique Aspect ) 

                          【地図主点(中心)】東経 135゚、北緯35

                          【主描画範囲】地図主点を中心とした90

                                              【境界緯度】φb20°【経度間隔】15゚【緯度間隔】10

 

ダウンロード
6-5-2-3-3_Airy_傾斜面.pdf
PDFファイル 414.1 KB

[6-5-2-3-3] Airy 図法 - 傾斜面 、半球並列( Airy Projection,Oblique Aspect )

                     【地図主点(中心)】左:東経 135゚、北緯35゚ 右:西経45゚、南緯35 

                         【主描画範囲】左右の地図主点を中心とした90 【境界緯度】φb20°

                         【経度間隔】15゚【緯度間隔】10

ダウンロード
6-5-2-3-3_Airy_傾斜面_半球並列.pdf
PDFファイル 398.1 KB