6-6 変更方位図法

 

   6-6-1 Aitoff (エイトフ図法)

        【 投影式 】D = arccos { cosφcos [ ( λ - λ0 ) / 2 ] }

もし D = 0 , x = 0, y = 0

 C = sinφ/ sin D

 x = ± 2 RD (1 - C2 ) 1/2   , 符号は(λ-λ0 )

 y = RDC

         【経度・緯度】  経線:曲線 、緯線:曲線

       【 ポイント 】・極は、点となるため緯線は -80°~ 80°を描画する。

  <基準経度・標準緯度・予備計算・共通数値 など>                
     記号  セルNo.         記述式                
      λ0     C2    ???  ← 中心経度(希望経度を入力)                
       R     C3       1  ← 描画係数                
                                                                         
  <データ計算 など>  経度緯度のデータ毎に記述式を複写(行コピー)する。
     記号  セルNo.         記述式
      No.     B9   ???  ← 式を複写する時に、一旦ソートしたり、解析時に役立つので連番号を付与
     経度     C9   ???  ← 実際の経度データ
     緯度     D9   ???  ← 実際の緯度データ
     補正
  λ-λ
0
    E9  =IF($C$2<0,IF(C9-$C$2>180,C9-$C$2-360,C9-$C$2),
                                    IF(C9-$C$2<-180,C9+360-$C$2,C9-$C$2))
 
      D     F9  =ACOS(COS(RADIANS(D9))*COS((RADIANS(E9/2))))
      C     G9  =SIN(RADIANS(D9))/SIN(F9)
      x     H9  =IF(F9=0,0,IF(E9<0,-2*F9*SQRT(1-G9^2),2*F9*SQRT(1-G9^2)))
      y     I9  =IF(F9=0,0,F9*G9)
     端CH     J10  =IF(H10="",0,IF(AND(ABS(H10)>0.2,H9*H10<0),"●",
                     IF(AND(H9<>"",H10>PI()/2,ABS(H9-H10)>0.2),"●",0)))
 
        左右の端をチェックしている。"●"の付いた行の前に一行挿入すると、勝手に左端と右端が線で結ばれない。

 

[6-6-1] エイトフ図法  ( Aitoff Projection ) 

【地図主点(中心)】東経 135゚、緯度 0゚ 【経度間隔】15゚ 【緯度間隔】10

ダウンロード
6-6-1_Aitoff Projection.pdf
PDFファイル 336.4 KB

  6-6-2 Hammer (Elliptical,ハンメル図法)

         【 投影式 】W = 0.5

 D = 2 / { 1 + cos φ cos [ W ( λ- λ0 ) ] }

 x = R (D1/2 / W) cos φ sin [ W ( λ - λ0 ) )

 y = R D1/2 sin φ

         【経度・緯度】  経線:曲線 、緯線:曲線

                【 ポイント 】極は、点となるため緯線は -80°~ 80°を描画する。

  <基準経度・標準緯度・予備計算・共通数値 など>                
     記号  セルNo.         記述式                
      λ0     C2    ???  ← 中心経度(希望経度を入力)                
       R     C3       1  ← 描画係数                
       W     C4    0.5                
                                                                         
  <データ計算 など>  経度緯度のデータ毎に記述式を複写(行コピー)する。
     記号  セルNo.         記述式
      No.     B9   ???  ← 式を複写する時に、一旦ソートしたり、解析時に役立つので連番号を付与
     経度     C9   ???  ← 実際の経度データ
     緯度     D9   ???  ← 実際の緯度データ
     補正
  λ-λ
0
    E9  =IF($C$2<0,IF(C9-$C$2>180,C9-$C$2-360,C9-$C$2),
                                    IF(C9-$C$2<-180,C9+360-$C$2,C9-$C$2))
 
      D     F9   =2/(1+COS(RADIANS(D9))*COS($C$4*(RADIANS(E9))))
      x     G9  =(SQRT(F9)/$C$4)*COS(RADIANS(D9))*SIN($C$4*RADIANS(E9))
      y     H9  =SQRT(F9)*SIN(RADIANS(D9))
     端CH     I10  =IF(G10="",0,IF(AND(ABS(G10)>0.2,G9*G10<0),"●",
                     IF(AND(G9<>"",G10>PI()/2,ABS(G9-G10)>0.2),"●",0))) 
 
        左右の端をチェックしている。"●"の付いた行の前に一行挿入すると、勝手に左端と右端が線で結ばれない。

 

[6-6-2] ハマー < Elliptical > 図法  ( Hammer < Elliptical > Projection )

【地図主点(中心)】東経 135゚、緯度 0゚ 【経度間隔】15゚ 【緯度間隔】10

ダウンロード
6-6-2_Hammer(Elliptical).pdf
PDFファイル 331.1 KB

  6-6-3 Eckert-Greifendorff (Hammer and Eckert-Greifendorff)

         【 投影式 】W= 0.25

 D = 2 / { 1 + cos φ cos [W( λ - λ0)] }

 x = R (D1/2 / W) cos φ sin [ W( λ - λ0)]

 y = R D1/2 sin φ

   W の数値以外は Hammer (Elliptical,ハンメル図法)に同じ

        【経度・緯度】  経線:曲線 、緯線:曲線

       【 ポイント 】極は、点となるため緯線は -80°~ 80°を描画する。

  <基準経度・標準緯度・予備計算・共通数値 など>                
     記号  セルNo.         記述式                
      λ0     C2    ???  ← 中心経度(希望経度を入力)                
       R     C3       1  ← 描画係数                
       W     C4    0.25                
                                                                         
  <データ計算 など>  経度緯度のデータ毎に記述式を複写(行コピー)する。
     記号  セルNo.         記述式
      No.     B9   ???  ← 式を複写する時に、一旦ソートしたり、解析時に役立つので連番号を付与
     経度     C9   ???  ← 実際の経度データ
     緯度     D9   ???  ← 実際の緯度データ
     補正
  λ-λ
0
    E9  =IF($C$2<0,IF(C9-$C$2>180,C9-$C$2-360,C9-$C$2),
                                    IF(C9-$C$2<-180,C9+360-$C$2,C9-$C$2))
 
      D     F9   =2/(1+COS(RADIANS(D9))*COS($C$4*(RADIANS(E9))))
      x     G9  =(SQRT(F9)/$C$4)*COS(RADIANS(D9))*SIN($C$4*RADIANS(E9))
      y     H9  =SQRT(F9)*SIN(RADIANS(D9))
     端CH     I10  =IF(G10="",0,IF(AND(ABS(G10)>0.2,G9*G10<0),"●",
                     IF(AND(G9<>"",G10>PI()/2,ABS(G9-G10)>0.2),"●",0))) 
 
        左右の端をチェックしている。"●"の付いた行の前に一行挿入すると、勝手に左端と右端が線で結ばれない。

 

[6-6-3] Eckert-Greifendorff 図法  ( Eckert-Greifendorff Projection )

【地図主点(中心)】東経 135゚、緯度 0゚ 【経度間隔】15゚ 【緯度間隔】10

ダウンロード
6-6-3_Eckert-Greifendorff.pdf
PDFファイル 306.1 KB

  6-6-4 Briesemeister

        【 投影式 】φ' = arcsin { [ sin φ - cos φ cos ( λ - λ0) ] / 21/2}

λ' = arccos { [sin φ + cos φ cos ( λ - λ0) ] / ( 21/2 cos φ') }

 D = 2 / [ 1 + cos φ' cos ( λ' / 2 ) ]

 x = ± R ( 3.5 D )1/2 cos φ' sin ( λ' / 2 ) 符号は ( λ - λ0 )

 y = R ( 2 D )1/2 sin φ' / 1.751/2

         【経度・緯度】  経線:曲線 、緯線:曲線

 【 ポイント 】計算エラーが発生するポイントがあった場合は、

                     『 6.地図投影の【エラーを回避する】 』を参照し

                      てください。

  <基準経度・標準緯度・予備計算・共通数値 など>                
     記号  セルNo.         記述式                
      λ0     C2    ???  ← 中心経度(希望経度を入力)                
       R     C3       1  ← 描画係数                
     長軸     C4  =SQRT(7)      ←外周は楕円となるが、その長軸                
     短軸     C5  =4/SQRT(7)   ←外周は楕円となるが、その短軸                
                                                                         
  <データ計算 など>  経度緯度のデータ毎に記述式を複写(行コピー)する。
     記号  セルNo.         記述式
      No.     B9   ???  ← 式を複写する時に、一旦ソートしたり、解析時に役立つので連番号を付与
     経度     C9   ???  ← 実際の経度データ
     緯度     D9   ???  ← 実際の緯度データ
     補正
  λ-λ
0
    E9  =IF($C$2<0,IF(C9-$C$2>180,C9-$C$2-360,C9-$C$2),
                                    IF(C9-$C$2<-180,C9+360-$C$2,C9-$C$2))
 
      φ'     F9  =ASIN((SIN(RADIANS(D9))-COS(RADIANS(D9))*COS(RADIANS(E9)))/SQRT(2))
      λ'     G9  =ACOS((SIN(RADIANS(D9))+COS(RADIANS(D9))*
                                                 COS(RADIANS(E9)))/(SQRT(2)*COS(F9)))
 
      D     H9  =2/(1+COS(F9)*COS(G9/2))
      x     I9  =IF(E9<0,-SQRT(3.5*H9)*COS(F9)*SIN(G9/2),SQRT(3.5*H9)*COS(F9)*SIN(G9/2))
      y     J9  =SQRT(2*H9)*SIN(F9)/SQRT(1.75)
     端CH     K10  =IF(I10="",0,IF(AND(ABS(I10)>0.2,I9*I10<0),"●",
                               IF(AND(I9<>"",I10>PI()/2,ABS(I9-I10)>0.2),"●",0)))
 
        左右の端をチェックしている。"●"の付いた行の前に一行挿入すると、勝手に左端と右端が線で結ばれない。

 

[6-6-4] Briesemeister 図法  ( Briesemeister Projection )

【地図主点(中心)】東経135゚、北緯45゚ 【経度間隔】15゚ 【緯度間隔】10

ダウンロード
6-6-4_Briesemeister_λ135°.pdf
PDFファイル 341.1 KB

[6-6-4] Briesemeister 図法  ( Briesemeister Projection )

【地図主点(中心)】東経10゚、北緯45゚ 【経度間隔】15゚ 【緯度間隔】10

ダウンロード
6-6-4_Briesemeister_λ 10°.pdf
PDFファイル 346.7 KB

  6-6-5 Winkel Tripel (ヴィンケル図法<3図法>)

         【 投影式 】cos P =cosφcos [ ( λ - λ0 ) /2 ]

 x = R { ( λ - λ0 ) cosφ1 +

                           2 P cosφsin [ ( λ - λ0 ) /2 ] / sin P} / 2

 y = R [ φ+ ( P sinφ) / sin P ] / 2

         【経度・緯度】  経線:曲線 、緯線:曲線

 【 ポイント 】・Equirectangular図法とエイトフ図法の算術平均で、面積、

                        方位、距離の3種類の歪みを最小限に抑えることを狙った

                        図法です。

                      ・同一投影式で φ1= 40°にしたバーソロミュ図法もある。

 

  <基準経度・標準緯度・予備計算・共通数値 など>                
     記号  セルNo.         記述式                
      λ0     C2    ???  ← 中心経度(希望経度を入力)                
       φ1     C3  =DEGREES(ACOS(2/PI()))  ← arccos 2/π =50゚28'                
       R     C4       1  ← 描画係数                
                                                                         
  <データ計算 など>  経度緯度のデータ毎に記述式を複写(行コピー)する。
     記号  セルNo.         記述式
      No.     B9   ???  ← 式を複写する時に、一旦ソートしたり、解析時に役立つので連番号を付与
     経度     C9   ???  ← 実際の経度データ
     緯度     D9   ???  ← 実際の緯度データ
     補正
  λ-λ
0
    E9  =IF($C$2<0,IF(C9-$C$2>180,C9-$C$2-360,C9-$C$2),
                                    IF(C9-$C$2<-180,C9+360-$C$2,C9-$C$2))
 
    cos P     F9  =COS(RADIANS(D9))*COS(RADIANS(E9/2))
       P     G9  =ACOS(F9)
    sin P     H9   =SIN(G9)
      x     I9  =(RADIANS(E9)*COS(RADIANS($C$3))+2*G9*
                            COS(RADIANS(D9))*SIN(RADIANS(E9/2))/H9)/2
 
      y     J9  =(RADIANS(D9)+G9*SIN(RADIANS(D9))/H9)/2
     端CH     K10  =IF(I10="",0,IF(AND(ABS(I10)>0.2,I9*I10<0),"●",
                            IF(AND(I9<>"",I10>PI()/2,ABS(I9-I10)>0.2),"●",0)))
 
        左右の端をチェックしている。"●"の付いた行の前に一行挿入すると、勝手に左端と右端が線で結ばれない。

 

[6-6-5] ヴィンケル第3図法 ( Winkel tripel projection )

【地図主点(中心)】東経 135゚、緯度 0゚ 【標準緯度】北緯5028

                                     【経度間隔】15゚ 【緯度間隔】10

ダウンロード
6-6-5_Winkel tripel_φ1=50°28'.pdf
PDFファイル 320.5 KB

  6-6-6 Wagner

        【 投影式 】S = 0.90631 sin φ

C0 = (1 - S2 )1/2

 C1 = (2 / {1 + C0 cos [ ( λ - λ0) / 3 ] } )1/2

 x = 2.66723 R C0 C1 sin [( λ - λ0)/3]

 y = 1.24104 R S C1

         【経度・緯度】  経線:曲線 、緯線:曲線

    【 ポイント 】極が窪んだ形状がめずらしい投影です。

  <基準経度・標準緯度・予備計算・共通数値 など>                
     記号  セルNo.         記述式                
      λ0     C2    ???  ← 中心経度(希望経度を入力)                
       R     C3       1  ← 描画係数                
                                                                         
  <データ計算 など>  経度緯度のデータ毎に記述式を複写(行コピー)する。
     記号  セルNo.         記述式
      No.     B9   ???  ← 式を複写する時に、一旦ソートしたり、解析時に役立つので連番号を付与
     経度     C9   ???  ← 実際の経度データ
     緯度     D9   ???  ← 実際の緯度データ
     補正
  λ-λ
0
    E9  =IF($C$2<0,IF(C9-$C$2>180,C9-$C$2-360,C9-$C$2),
                                    IF(C9-$C$2<-180,C9+360-$C$2,C9-$C$2))
 
      C0     F9  =SQRT(1-(0.90631*SIN(RADIANS(D9)))^2)
      C0     G9  =SQRT(2/(1+F9*COS(RADIANS(E9/3))))
      x     H9   =2.66723*F9*G9*SIN(RADIANS(E9/3))
      y     I9  =1.24104*0.90631*SIN(RADIANS(D9))*G9
     端CH     J10  =IF(H10="",0,IF(AND(ABS(H10)>0.2,H9*H10<0),"●",
                     IF(AND(H9<>"",H10>PI()/2,ABS(H9-H10)>0.2),"●",0)))
 
        左右の端をチェックしている。"●"の付いた行の前に一行挿入すると、勝手に左端と右端が線で結ばれない。

 

[6-6-6] Wagner Ⅶ 図法  ( WagnerProjection )

【地図主点(中心)】東経 135゚、緯度 0゚ 【経度間隔】15゚ 【緯度間隔】10

ダウンロード
6-6-6_Wagner Ⅶ Projection.pdf
PDFファイル 345.5 KB

  6-6-7 Two-Point Equidistant (2点正距図法)

        【 投影式 】cos z0 = sin φA sin φB + cos φA cos φB cos (λB- λA)

cos zA = sin φA sin φ + cos φA cos φ cos (λ - λA)

 cos zB = sin φB sin φ + cos φB cos φ cos (λ - λB)

 x = R ( z A2 z B2) / (2 z0)

 y = ± R [4 z02 zB2- ( z02 - zA2+ zB2)2]1/2 / (2 z0)

 y の符号→[ cos φA cos φB sin (λB - λA) sin φ-

 cos φA sin φB cos φsin (λ - λA) +

         sin φA cos φB cos φ sin (λ - λB)]

 もし  (z0+ zA+ zB) = 2 π yの符号 = 0 となるので、

そのままの y を使う

 外周楕円長軸 = R π [1 - z0 / ( 2 π )]

 外周楕円短軸 = R π (1 - z0 / π )l/2

         【経度・緯度】  経線:曲線 、緯線:曲線

 【 ポイント 】・描画形状は、楕円になる。

            ・意図せず上下(y 軸方向)が結ばれないようにチェック必要。

  <基準経度・標準緯度・予備計算・共通数値 など>                
            セルNo.         記述式                
        λA     C2   ???    基準点A経度(希望経度を入力)                
        φA     C3   ???    基準点A緯度(希望緯度を入力)                
        λB     C4   ???    基準点B経度(希望経度を入力)                
        φB     C5   ???    基準点B緯度(希望緯度を入力)                
        R      C6     1                
   λAラジアン     D2  =RADIANS(C2)  ← λAのラジアン変換                
   φAラジアン     D3  =RADIANS(C3)  ← φAのラジアン変換                
   λBラジアン     D4  =RADIANS(C4)  ← λBのラジアン変換                
   φBラジアン     D5  =RADIANS(C5)  ← φBのラジアン変換                
    ※基準点が2点なのでラジアン変換をここで行い、投影式への関数入力を軽減している。
                                                                         
  <予備計算・共通数値 など>
            セルNo.         記述式
     cos z0     J2   =SIN($D$3)*SIN($D$5)+COS($D$3)*
                COS($D$5)*COS(RADIANS($C$4-$C$2))
 
        z0     J3   =ACOS(J2)
   予備計算1      J4   =COS($D$3)*COS($D$5)*SIN(RADIANS($C$4-$C$2))
   予備計算2      J5   =COS($D$3)*SIN($D$5)
   予備計算3      J6   =SIN($D$3)*COS($D$5)
    楕円長軸     M2   =PI()*(1-$J$3/(2*PI()))
    楕円短軸      M3   =PI()*SQRT(1-$J$3/PI())
                                                                         
  <データ計算 など>  経度緯度のデータ毎に記述式を複写(行コピー)する。
     記号  セルNo.         記述式
      No.     B9   ???  ← 式を複写する時に、一旦ソートしたり、解析時に役立つので連番号を付与
     経度     C9   ???  ← 実際の経度データ
     緯度     D9   ???  ← 実際の緯度データ
   補正
 λ-λ
A
    E9  =IF($C$2<0,IF(C9-$C$2>180,C9-$C$2-360,
                    C9-$C$2),IF(C9-$C$2<-180,C9+360-$C$2,C9-$C$2))
 
   補正
 λ-λ
B
    F9  =IF($C$4<0,IF(C9-$C$4>180,C9-$C$4-360,
                    C9-$C$4),IF(C9-$C$4<-180,C9+360-$C$4,C9-$C$4))
 
   cos zA     G9  =SIN($D$3)*SIN(RADIANS(D9))+COS($D$3)*
                      COS(RADIANS(D9))*COS(RADIANS(E9))
 
   cos zB     H9   =SIN($D$5)*SIN(RADIANS(D9))+COS($D$5)*
                      COS(RADIANS(D9))*COS(RADIANS(F9))
 
      zA     I9   =ACOS(G9)
      zB     J9   =ACOS(H9)
 

  符号

    y

    K9   =$J$4*SIN(RADIANS(D9))-$J$5*COS(RADIANS(D9))*
    SIN(RADIANS(C9-$C$2))+$J$6*COS(RADIANS(D9))*SIN(RADIANS(C9-$C$4))
 
      x     L9   =(I9^2-J9^2)/(2*$J$3)
      y     M9  =IF(K9<0,-SQRT(4*$J$3^2*J9^2-($J$3^2-I9^2+J9^2)^2)/
                       (2*$J$3),SQRT(4*$J$3^2*J9^2-($J$3^2-I9^2+J9^2)^2)/(2*$J$3))
 
   端CH      N10  =IF(M10="",0,IF(AND(ABS(M10)>0.2,M9*M10<0),"●",
                       IF(AND(M9<>"",M10>PI()/2,ABS(M9-M10)>0.2),"●",0)))
 
  方位角      O9    ???  ← 外周描画用方位角。行方向に 1~360°を展開する。
      x'      P9  =$M$2*COS(RADIANS(O9))
      y'      Q9  =$M$3*SIN(RADIANS(O9))

 

[6-6-7] 2点正距図法 ( Two-Point Equidistant Projection

                           【地図基準点①】東経   0゚、北緯5128' ( グリニッジ,London )

                           【地図基準点②】東経 135゚、北緯3500' ( 日本ヘソ公園,西脇市 )

                                             【経度間隔】15゚ 【緯度間隔】10

ダウンロード
6-6-7_Two-Point Equidistant.pdf
PDFファイル 346.0 KB

  6-6-8 Wiechel (north polar aspect only)

         【 投影式 】x = R [ sin( λ - λ0) cosφ- cos( λ - λ0) (1 - sinφ) ]

                                         y = -R [ cos( λ - λ0) cosφ + sin( λ - λ0) (1 - sinφ) ]

         【経度・緯度】  経線:曲線 、緯線:曲線

         【ポイント】・中心経度と描画した見た目の中心がズレます。描画後を見な

                       がら中心経度を調整してください。

                             ・参考文献(An Album of Map Projections)では『北極専用』とあっ

                              たが『南極』もアレンジしてみた。

  <基準経度・標準緯度・予備計算・共通数値 など>                
     記号  セルNo.         記述式                
      λ0     C2    ???  ← 中心経度(希望経度を入力)                
       R     C3       1  ← 描画係数                
                                                                         
  <データ計算 など>  経度緯度のデータ毎に記述式を複写(行コピー)する。
     記号  セルNo.         記述式
      No.     B9   ???  ← 式を複写する時に、一旦ソートしたり、解析時に役立つので連番号を付与
     経度     C9   ???  ← 実際の経度データ
     緯度     D9   ???  ← 実際の緯度データ
     補正
  λ-λ
0
    E9  =IF($C$2<0,IF(C9-$C$2>180,C9-$C$2-360,C9-$C$2),
                                    IF(C9-$C$2<-180,C9+360-$C$2,C9-$C$2))
 
    1-sinφ     F9  =1-SIN(RADIANS(D9))
      x     G9  =SIN(RADIANS(E9))*COS(RADIANS(D9))-COS(RADIANS(E9))*F9
      y     H9  =-1*(COS(RADIANS(E9))*COS(RADIANS(D9))+SIN(RADIANS(E9))*F9)

 

[6-6-8] Wiechel 図法  (Wiechel Projection<north polar aspect only>)   北極面

【地図主点(中心)】東経 105゚、北緯90゚ 【経度間隔】15゚ 【緯度間隔】10

ダウンロード
6-6-8_Wiechel_北極面.pdf
PDFファイル 381.4 KB

[6-6-8] Wiechel 図法  (Wiechel Projection<south polar aspect only>)   南極面

         南極面にするには経度緯度の符号を反転させるだけでよい。ラベルは

         反転させる前のまま用いる。

【地図主点(中心)】西経 90゚、南緯90゚ 【経度間隔】15゚ 【緯度間隔】10


  6-6-9 Tilted Perspective

        【 投影式 】A = { ( y1 cos γ + x1 sin γ ) sin ω / [ R ( P- 1) ] } + cos ω

cos z = sinφ1 sinφ+ cosφ1 cosφcos( λ - λ0 )

 K=( P-1 )/( P-cos z )

 x1=RKcosφsin( λ - λ0 )

 y1=RK[cosφ1 sinφ-sinφ1 cosφcos( λ - λ0 )]

 x = ( x1 cos γ- y1 sin γ ) cos ω / A

 y = ( y1 cos γ + x1 sin γ) / A

 もし  cos z <1/P  は描画しない

         【経度・緯度】  経線:曲線 、緯線:曲線

         【ポイント】・バードビューのような投影図が描画できます。

                     ・投影アングルによっては、地球外周を描画する場合がありま

                      すが、参考文献では具体的な外周式が見つかりません、

                      しかし『 cos z <1/P  は、「不等号」を「=」にすれば描画

                      のが特定できることがわかります。

                      そこで

 cos z = sinφ1 sinφ+ cosφ1 cosφcos( λ - λ0 ) = 1/P

                                                                          ↓↓↓↓↓↓↓

                                                                 λ = arccos[(1/P - sinφ1 sinφ)/( cosφ1 cosφ)] + λ0
 

                      ここでφ1は、設定値として係数化できるので φ変化させて

                       λ を算出し、投影式に投入すれば外周が描画できます。

                       φは、90°~- 90°の範囲だけでなく地球裏面も考慮して360°

                      変化させます。

                       また、φを0.5°程度のピッチで変化させると、一部がエラーと

                      連続線となりません。

しかし x y がエラーとなるφの前または後ろのφを

小刻みに変化させるとエラーとなった窪みはどんど

狭くなって行きます。しかし、中心点などを変え

るたびにセットするのは大変です。そこで描画をよ

く見ると全体として楕円のようになっています。

楕円なら長軸と短軸がわかれば描画できます。

そこで、エラーのx y は、IF関数を使って0」に

置き換え、算出した x y それぞれの最大最小を求め、

楕円長軸、短軸を算出し『楕円』を描画し外周とし

ます。エラーを「0」とするのは、最大値と最小値は、

正または負となりゼロにはならないので、算出結果の

                            範囲に

                              =MAX(???:???) , =MIN(???,???)

                             を適用して長軸と短軸を求めたいからです。念のた

                            め上図のように実際に描画して見て、最大値、最小

                            値が描画されていることを確認して用いてください。

 

                ※どなたかもっとスマートな計算式をご存知な方は

                 それを使って投影描画してみてください。

 

  <基準経度・標準緯度・予備計算・共通数値 など>                
     記号  セルNo.         記述式                
      λ0     C2     ???  ← 中心経度(希望経度を入力)                
      φ1     C3      ??   中心緯度 (希望緯度を入力)                
  地球半径     C4   6,370  ← 単位は、km です                
  視点高度     C5    ????  ← 単位は、km です                 
                                                                         
  <設定値・予備計算 など>
     記号  セルNo.         記述式                
      γ      G2    ???  ← 方位角                
      ω      G3      ??  ← 傾き角                
      P      G4   =($C$4+$C$5)/$C$4                
    1 /  P      G5   =1/$G$4                
                                                                         
  <外周用楕円長軸、短軸計算>                
     記号  セルNo.         記述式                
    x Max     V2   =MAX(V9:V????)  ← ????は、V列の最終行                
    x Min     V3   =MIN(V9:V????)  ← ????は、V列の最終行                
  横軸半径     V4   =(V2-V3)/2                
    y Max     W2   =MAX(W9:W????)  ← ????は、W列の最終行                
    y Min     W3   =MIN(W9:W????)  ← ????は、W列の最終行                
  縦軸半径     W4   =(W2-W3)/2                
                                                                         
  <データ計算 など>  経度緯度のデータ毎に記述式を複写(行コピー)する。
   区分    記号  セルNo.         記述式                                              
   

 

 
    No.     B9   ???  ← 式を複写する時に、一旦ソートしたり、解析時に役立つので連番号を付与        
     経度     C9   ???  ← 実際の経度データ                                      
     緯度     D9   ???  ← 実際の緯度データ                                      
     補正
  λ-λ
0
    E9  =IF($C$2<0,IF(C9-$C$2>180,C9-$C$2-360,C9-$C$2),
                                    IF(C9-$C$2<-180,C9+360-$C$2,C9-$C$2))
 
     cos z      F9   =SIN(RADIANS($C$3))*SIN(RADIANS(D9))+COS(RADIANS($C$3))*
                                            COS(RADIANS(D9))*COS(RADIANS(E9))
 
       K      G9  =($G$4-1)/($G$4-F9)
       x1     H9  =G9*COS(RADIANS(D9))*SIN(RADIANS(E9))
       y1     I9  =G9*(COS(RADIANS($C$3))*SIN(RADIANS(D9))-SIN(RADIANS($C$3))*
                                           COS(RADIANS(D9))*COS(RADIANS(E9)))
 
       A      J9  =((I9*COS(RADIANS($G$2))+H9*SIN(RADIANS($G$2)))*
                           SIN(RADIANS($G$3)))/($G$4-1)+COS(RADIANS($G$3))
 
        x      K9  =((H9*COS(RADIANS($G$2))-I9*SIN(RADIANS($G$2)))*COS(RADIANS($G$3)))/J9
        y      L9   =(I9*COS(RADIANS($G$2))+H9*SIN(RADIANS($G$2)))/J9
   描画CH     M9  =IF(F9<$G$5,"●",0)
   

 

 

 
  外周λ     N9  =IF(DEGREES(ACOS(($G$5-SIN(RADIANS($C$3))*SIN(RADIANS(O9)))/
      (COS(RADIANS($C$3))*COS(RADIANS(O9))))+
        RADIANS($C$2))>180,DEGREES(ACOS(($G$5-SIN(RADIANS($C$3))*
          SIN(RADIANS(O9)))/(COS(RADIANS($C$3))*COS(RADIANS(O9))))+
            RADIANS($C$2))-360,DEGREES(ACOS(($G$5-SIN(RADIANS($C$3))*
              SIN(RADIANS(O9)))/(COS(RADIANS($C$3))*COS(RADIANS(O9))))+
                 RADIANS($C$2)))        ← 外周描画 λ
 
 
 
 
 
 
      φ     O9   0  ← 0をスタートに0.5ピッチで360°まで O列に展開する   ← 外周描画 φ
     補正
  λ-λ
0
    P9  =IF($C$2<0,IF(N9-$C$2>180,N9-$C$2-360,N9-$C$2),
                                          IF(N9-$C$2<-180,N9+360-$C$2,N9-$C$2))
 
     cos z      Q9  =SIN(RADIANS($C$3))*SIN(RADIANS(O9))+COS(RADIANS($C$3))*
                                          COS(RADIANS(O9))*COS(RADIANS(P9))
 
       K      R9  =($G$4-1)/($G$4-Q9)
       x1     S9  =R9*COS(RADIANS(O9))*SIN(RADIANS(P9))
       y1     T9  =R9*(COS(RADIANS($C$3))*SIN(RADIANS(O9))-
               SIN(RADIANS($C$3))*COS(RADIANS(O9))*COS(RADIANS(P9)))
 
       A      U9  =((T9*COS(RADIANS($G$2))+S9*SIN(RADIANS($G$2)))*
                          SIN(RADIANS($G$3)))/($G$4-1)+COS(RADIANS($G$3))
 
       x      V9  =IF(ISERROR(Q9),0,((S9*COS(RADIANS($G$2))-
                           T9*SIN(RADIANS($G$2)))*COS(RADIANS($G$3)))/U9)
 
       y      W9  =IF(ISERROR(Q9),0,(T9*COS(RADIANS($G$2))+S9*SIN(RADIANS($G$2)))/U9)
   
 
   角度     X9   0  ← 0をスタートに1.0ピッチで360°まで X列下方に展開する
        x      Y9  =$V$4*COS(RADIANS(X9))      ← 外周描画用 x
        y      Z9  =$W$4*SIN(RADIANS(X9))-($W$4-$W$2)     ← 外周描画用 y
   ※経線、緯線は「海岸線」と同じように計算する。

 

[6-6-9] Tilted Perspective Projection

                  【視点経度緯度】東経 135゚、北緯35(ニホンヘソ公園、西脇市)

                  【視点地表高度】1,800m(地球半径は6,370kmで計算) 【傾斜上向き角】20

                              【方位角】330(基準:北を 0)【経度緯度間隔】1

ダウンロード
6-6-9_TILTED PERSPECTIVE.pdf
PDFファイル 2.6 MB

  6-6-10 Littrow

        【 投影式 】x = R sin (λ- λ0) / cos φ

y = R tanφ cos (λ - λ0)

         【経度・緯度】  経線:曲線 、緯線:曲線

         【 ポイント 】中心経度±90°の範囲外は、折り返して描画されるので                       描画対象から外す。

  <基準経度・標準緯度・予備計算・共通数値 など>                
     記号  セルNo.         記述式                
      λ0     C2     ???  ← 中心経度(希望経度を入力)                
  左端経度     C3  =IF(C2-90<-180,C2-90+360,C2-90)   ← 左端の折り返しポイント                
  右端経度     C4  =IF(C2+90>180,C2-270,C2+90)         ← 右端の折り返しポイント                
       R      C5    1                
                                                                         
  <データ計算 など>  経度緯度のデータ毎に記述式を複写(行コピー)する。
     記号  セルNo.         記述式
      No.     B9   ???  ← 式を複写する時に、一旦ソートしたり、解析時に役立つので連番号を付与
     経度     C9   ???  ← 実際の経度データ
     緯度     D9   ???  ← 実際の緯度データ
     補正
  λ-λ
0
    E9  =IF($C$2<0,IF(C9-$C$2>180,C9-$C$2-360,C9-$C$2),
                                    IF(C9-$C$2<-180,C9+360-$C$2,C9-$C$2))
 
       x      F9  =SIN(RADIANS(E9))/COS(RADIANS(D9))
       y      G9  =TAN(RADIANS(D9))*COS(RADIANS(E9))
     端CH      H9  =IF($C$3=0,IF(C9<0,"●",0),IF($C$3>0,IF(OR(AND(C9>=0,C9<$C$3),
     AND(C9<=0,C9>$C$4)),"●",0),IF($C$3<0,IF(OR(C9<$C$3,C9>$C$4),"●",0),0)))
 
     ↑ 「●」印は描画しない。 

 

[6-6-10] リットロウ図法 ( Littrow projection

【地図主点(中心)】東経 135゚、緯度 0゚ 【経度間隔】15゚ 【緯度間隔】10

ダウンロード
6-6-10_Littrow Projection.pdf
PDFファイル 2.2 MB

  6-6-11 Craig Retroazimuthal

        【 投影式 】もし  (λ - λ0) = 0,

x = 0

 y = R (sin φ - cos φ tan φ1)

 もし  (λ - λ0) ≠ 0,

 x = R (λ- λ0)

 y = R (λ- λ0) [sin φcos (λ- λ0) - cos φtan φ1] / sin (λ- λ0)

         【経度・緯度】  経線:直線 、緯線:曲線

       ポイント 】緯度描画データは、中心緯度から離れるに従い裏返ってい

ます。その裏返る地点を求める式が入手できませんでした。

⇒原始的()な方法ですが、該当緯度毎に

  0.001を引いた(北半球に中心緯度があるので)

                        点の y を算出し裏返りを確認して、描画の可否

                        を判定する。

  <基準経度・標準緯度・予備計算・共通数値 など>                
     記号  セルNo.         記述式                
      λ0     C2     ???  ← 中心経度(希望経度を入力)                
      φ1     C3      ??   ← 中心緯度   (希望緯度を入力)                
       R      C4    1                
                                                                         
  <データ計算 など>  経度緯度のデータ毎に記述式を複写(行コピー)する。
     記号  セルNo.         記述式
      No.     B9   ???  ← 式を複写する時に、一旦ソートしたり、解析時に役立つので連番号を付与
     経度     C9   ???  ← 実際の経度データ
     緯度     D9   ???  ← 実際の緯度データ
     補正
  λ-λ
0
    E9  =IF($C$2<0,IF(C9-$C$2>180,C9-$C$2-360,C9-$C$2),
                                    IF(C9-$C$2<-180,C9+360-$C$2,C9-$C$2))
 
       x      F9  =IF(E9=0,0,RADIANS(E9))
       y      G9   =IF(E9=0,SIN(RADIANS(D9))-COS(RADIANS(D9))*
    TAN(RADIANS($C$3)),RADIANS(E9)*(SIN(RADIANS(D9))*
     COS(RADIANS(E9))-COS(RADIANS(D9))*TAN(RADIANS($C$3)))/SIN(RADIANS(E9)))
 
 
   y-0.001      H9  =IF(E9=0,SIN(RADIANS(D9-0.001))-COS(RADIANS(D9-0.001))*
       TAN(RADIANS($C$3)),RADIANS(E9)*(SIN(RADIANS(D9-0.001))*
          COS(RADIANS(E9))-COS(RADIANS(D9-0.001))*TAN(RADIANS($C$3)))/
                SIN(RADIANS(E9)))
 
 
 
     端CH     I9  =IF(AND(D9<=0,H9>G9),"●",0)
 
     ↑ 「●」印は描画しない。 

 

[6-6-11] クレイグ Retroazimuthal 図法  ( Craig Retroazimuthal Projection )

【地図主点(中心)】東経 135゚、北緯 35(日本ヘソ公園、西脇市)

                                                               【経度間隔】15゚ 【緯度間隔】10

ダウンロード
6-6-11_Craig Retroazimuthal.pdf
PDFファイル 3.2 MB

  6-6-12 Hammer Retroazimuthal

        【 投影式 】cos z = sinφ1 sinφ + cosφ1 cosφ cos (λ - λ0)

K= z / sin z

 x = RK cos φ1 sin (λ - λ0)

 y = - RK [sin φ1 cos φ- cos φ1 sin φ cos (λ - λ0)]

         【経度・緯度】  経線:曲線 、緯線:曲線

        【 ポイント 】中央経度から±90°を外れた部分は表示しない。

  <基準経度・標準緯度・予備計算・共通数値 など>                
     記号  セルNo.         記述式                
      λ0     C2     ???  ← 中心経度(希望経度を入力)                
      φ1     C3      ??   ← 中心緯度   (希望緯度を入力)                
       R      C4    1                
                                                                         
  <データ計算 など>  経度緯度のデータ毎に記述式を複写(行コピー)する。
     記号  セルNo.         記述式
      No.     B9   ???  ← 式を複写する時に、一旦ソートしたり、解析時に役立つので連番号を付与
     経度     C9   ???  ← 実際の経度データ
     緯度     D9   ???  ← 実際の緯度データ
     補正
  λ-λ
0
    E9  =IF($C$2<0,IF(C9-$C$2>180,C9-$C$2-360,C9-$C$2),
                                    IF(C9-$C$2<-180,C9+360-$C$2,C9-$C$2))
 
     cos z      F9  =SIN(RADIANS($C$3))*SIN(RADIANS(D9))+COS(RADIANS($C$3))*
                                                       COS(RADIANS(D9))*COS(RADIANS(E9))
 
       z      G9   =ACOS(F9)
      K      H9  =G9/SIN(G9)
      x     I9   =H9*COS(RADIANS($C$3))*SIN(RADIANS(E9))
      y     J9  =-H9*(SIN(RADIANS($C$3))*COS(RADIANS(D9))-
                           COS(RADIANS($C$3))*SIN(RADIANS(D9))*COS(RADIANS(E9)))
 
     端CH     K9  =IF(OR(E9<-90,E9>90),"●",0) 

 

[6-6-12]  Hammer Retroazimuthal 図法  ( Hammer Retroazimuthal Projection )

【地図主点(中心)】東経 135゚、北緯 35゚【経度間隔】15゚【緯度間隔】10

ダウンロード
6-6-12_Hammer Retroazimuthal.pdf
PDFファイル 200.2 KB

  6-6-13 Berghaus Star (ベルガウス星影図法)

        【 投影式 】北半球を中心とする場合を想定しています。

もし φ>=0 (北半球),

 x = R ( π/2 - φ) sin (λ - λ0)

 y = -R ( π/2 - φ) cos (λ - λ0)

 もし φ < 0 (南半球),

  C = cos( λ - λ0) - 2 cos ( λn - λ0)

 D = sin ( λ - λ0) - 2 sin ( λn - λ0)

                                                      x = - [ π R sin ( λ- λn) + y D ) ] C

                                         y = R {- π D sin ( λ - λn )+

                                                      C [ ( π/2 - φ)2 (5 - 4 cos (λ - λn )) –

                                                                π2 sin2 ( λ - λn)]1/2}[5 - 4 cos ( λ - λn)]

 ただし C = 0,

 x= ± R (π/2 -φ)  符号は  sin (λn - λ0)

 通常は、λ1 = λ0 とする。

         【経度・緯度】  経線:直線 、緯線:曲線

         【 ポイント 】・5角形になるので、南半球は5つの部分にデータを分けて

                        おきます。

                      ・経線、緯線などの補助線も5つの部分に分けてください。

                     ・北半球は分割しなくてよい。

  <基準経度・標準緯度・予備計算・共通数値 など>  
     記号  セルNo.         記述式  
      λ0     C2     ???  ← 中心経度(希望経度を入力)  
       R      C3       1  ← 描画係数  

 

 <5分割の中央経度と範囲を特定する>

            [5分割の入力イメージ]

   区分    記号  セルNo.         記述式                                              
    λ1  λ1左端     F3  =IF(F4-360/10<-180,F4-360/10+360,F4-360/10)
   λ1     F4  =$C$2
   λ1右端     F5  =IF(F4+360/10<-180,F4+360/10+360,IF(F4+360/10>180,
                                                      -180+(F4+360/10-180),F4+360/10))
 
    λ2  λ2左端     G3  =IF(G4-360/10<-180,G4-360/10+360,G4-360/10)
   λ2     G4  =IF(F4-360/5<-180,F4-360/5+360,F4-360/5)
   λ2右端     G5  =IF(G4+360/10<-180,G4+360/10+360,IF(G4+360/10>180,
                                                      -180+(G4+360/10-180),G4+360/10))
 
    λ3  λ3左端     H3  =IF(H4-360/10<-180,H4-360/10+360,H4-360/10)
   λ3     H4  =IF(G4-360/5<-180,G4-360/5+360,G4-360/5)
   λ3右端     H5  =IF(H4+360/10<-180,H4+360/10+360,IF(H4+360/10>180,
                                                      -180+(H4+360/10-180),H4+360/10))
 
    λ4  λ4左端     I3  =IF(I4-360/10<-180,I4-360/10+360,I4-360/10)
   λ4     I4  =IF(H4-360/5<-180,H4-360/5+360,H4-360/5)
   λ4右端     I5  =IF(I4+360/10<-180,I4+360/10+360,IF(I4+360/10>180,
                                                         -180+(I4+360/10-180),I4+360/10))
 
    λ5  λ5左端     J3  =IF(J4-360/10<-180,J4-360/10+360,J4-360/10)
   λ5     J4  =IF(I4-360/5<-180,I4-360/5+360,I4-360/5)
   λ5右端     J5  =IF(J4+360/10<-180,J4+360/10+360,IF(J4+360/10>180,
                                                        -180+(J4+360/10-180),J4+360/10))
 
                                                                         
  <データ計算 など>  経度緯度のデータ毎に記述式を複写(行コピー)する。
     記号  セルNo.         記述式
      No.     B9   ???  ← 式を複写する時に、一旦ソートしたり、解析時に役立つので連番号を付与
     経度     C9   ???  ← 実際の経度データ
     緯度     D9   ???  ← 実際の緯度データ
      x     E9  =(PI()/2-RADIANS(D9))*SIN(RADIANS(C9-$C$2))
      y     F9  =-(PI()/2-RADIANS(D9))*COS(RADIANS(C9-$C$2))
   λ1No.     G9   ???  ← 式を複写する時に、一旦ソートしたり、解析時に役立つので連番号を付与
   λ1経度     H9   ???  ← 実際の南半球のλ1経度データ
   λ1緯度     I9   ???  ← 実際の南半球のλ1緯度データ
   λ1C     J9   =COS(RADIANS(H9-$C$2))-2*COS(RADIANS($F$4-$C$2))
   λ1D     K9  =SIN(RADIANS(H9-$C$2))-2*SIN(RADIANS($F$4-$C$2))
   λ1x     L9  =IF(J9=0,SIGN(SIN(RADIANS($F$4-$C$2)))*(PI()/2-RADIANS(I9)),
                                               -(PI()*SIN(RADIANS(H9-
$F$4
))+M9*K9)/J9)
 
   λ1y     M9  =(-PI()*K9*SIN(RADIANS(H9-$F$4))+J9*SQRT((PI()/2-RADIANS(I9))*(PI()/2-
              RADIANS(I9))*(5-4*COS(RADIANS(H9-
$F$4)))-PI()*PI()*
                    (SIN(RADIANS(H9-
$F$4)))*(SIN(RADIANS(H9-$F$4)))))/
                            (5-4*COS(RADIANS(H9-
$F$4
)))
 
 
 
   ↑ 以下、λ2~λ5まで展開する( 赤文字の$F$4を該当λn のセルに変更すればよい )。

 

[6-6-13-1]  ベルガウス星影図法  ( Berghaus Star projection )

【地図主点(中心)】東経 135゚、北緯 90゚【経度間隔】15゚【緯度間隔】10

ダウンロード
6-6-13-1_Berghaus Star.pdf
PDFファイル 318.7 KB

  以上で描画できましたが、何となく違和感があります。普通星といえば『☆』というイメ

  ージですが、現在は逆立ちした星形のようです。では、正立した星形を検討してみます。

   星形投影式を考えるのは、難しいようです。そこで形状に着目して見ると、現在の

   ものを 180°回転させると『☆』となります。

   幸い、投影式にて算出した中心は x=0, y=0 となりますので算出した x , y の符号

   を反転をさせれば 180°回転させられます。但し、回転させると当然中心部も回転

   します。例えば、今まで日本が中心だと思ったものが、逆さまの日本になってしま

   うため、投影中心の経度を反転させた経度にする必要があります。

   

        λ0 λ0 例:東経135°⇒ 西経 45°

 

         【経度・緯度】  経線:直線 、緯線:曲線

         【 ポイント 】・南半球は5つの部分にを分けておきます。データは前述した

            星形とは分割点が変わります。

                      ・経線、緯線などの補助線も5つの部分に分けてください。

                      ・北半球は分割しなくてよい。

 

  <基準経度・標準緯度・予備計算・共通数値 など>  
     記号  セルNo.         記述式  
      λ0     C2    ???  ← 中心経度(希望経度を入力)  
      λ0'     C3  =IF(C2-180<-180,C2+180,C2-180)  
       R     C4       1  ← 描画係数  

 

 <5分割の中央経度と範囲を特定する>

            [5分割の入力イメージ]

   区分    記号  セルNo.         記述式                                              
    λ1  λ1左端     F3  =IF(F4-360/10<-180,F4-360/10+360,F4-360/10)
   λ1     F4  =$C$3
   λ1右端     F5  =IF(F4+360/10<-180,F4+360/10+360,IF(F4+360/10>180,
                                                      -180+(F4+360/10-180),F4+360/10))
 
    λ2  λ2左端     G3  =IF(G4-360/10<-180,G4-360/10+360,G4-360/10)
   λ2     G4  =IF(F4-360/5<-180,F4-360/5+360,F4-360/5)
   λ2右端     G5  =IF(G4+360/10<-180,G4+360/10+360,IF(G4+360/10>180,
                                                      -180+(G4+360/10-180),G4+360/10))
 
    λ3  λ3左端     H3  =IF(H4-360/10<-180,H4-360/10+360,H4-360/10)
   λ3     H4  =IF(G4-360/5<-180,G4-360/5+360,G4-360/5)
   λ3右端     H5  =IF(H4+360/10<-180,H4+360/10+360,IF(H4+360/10>180,
                                                      -180+(H4+360/10-180),H4+360/10))
 
    λ4  λ4左端     I3  =IF(I4-360/10<-180,I4-360/10+360,I4-360/10)
   λ4     I4  =IF(H4-360/5<-180,H4-360/5+360,H4-360/5)
   λ4右端     I5  =IF(I4+360/10<-180,I4+360/10+360,IF(I4+360/10>180,
                                                        -180+(I4+360/10-180),I4+360/10))
 
    λ5  λ5左端     J3  =IF(J4-360/10<-180,J4-360/10+360,J4-360/10)
   λ5     J4  =IF(I4-360/5<-180,I4-360/5+360,I4-360/5)
   λ5右端     J5  =IF(J4+360/10<-180,J4+360/10+360,IF(J4+360/10>180,
                                                        -180+(J4+360/10-180),J4+360/10))
 
                                                                         
  <データ計算 など>  経度緯度のデータ毎に記述式を複写(行コピー)する。
     記号  セルNo.         記述式
      No.     B9   ???  ← 式を複写する時に、一旦ソートしたり、解析時に役立つので連番号を付与
     経度     C9   ???  ← 実際の経度データ
     緯度     D9   ???  ← 実際の緯度データ
      x     E9  =-(PI()/2-RADIANS(D9))*SIN(RADIANS(C9-$C$3))
      y     F9  =(PI()/2-RADIANS(D9))*COS(RADIANS(C9-$C$3))
   λ1No.     G9   ???  ← 式を複写する時に、一旦ソートしたり、解析時に役立つので連番号を付与
   λ1経度     H9   ???  ← 実際の南半球のλ1経度データ
   λ1緯度     I9   ???  ← 実際の南半球のλ1緯度データ
   λ1C     J9  =COS(RADIANS(H9-$C$3))-2*COS(RADIANS($F$4-$C$3))
   λ1D     K9  =SIN(RADIANS(H9-$C$3))-2*SIN(RADIANS($F$4-$C$3))
   λ1x     L9  =-IF(J9=0,SIGN(SIN(RADIANS($F$4-$C$3)))*(PI()/2-RADIANS(I9)),
                                                          -(PI()*SIN(RADIANS(H9-
$F$4
))-M9*K9)/J9)
 
   λ1y     M9  =-(-PI()*K9*SIN(RADIANS(H9-$F$4))+J9*SQRT((PI()/2-RADIANS(I9))*
       (PI()/2-RADIANS(I9))*(5-4*COS(RADIANS(H9-
$F$4)))-PI()*PI()*
                  (SIN(RADIANS(H9-
$F$4)))*(SIN(RADIANS(H9-$F$4)))))/
                       (5-4*COS(RADIANS(H9-
$F$4
)))
 
 
 
   ↑ 以下、λ2~λ5まで展開する( 赤文字の$F$4を該当λn のセルに変更すればよい )。

 

[6-6-13-2]  正立 ベルガウス星影図法  ( Berghaus Star projection )

【地図主点(中心)】東経 135゚、北緯 90゚【経度間隔】15゚【緯度間隔】10

ダウンロード
6-6-13-2_Berghaus Star.pdf
PDFファイル 317.8 KB

  6-6-14 Two-Point Azimuthal (2点方位図法)

 

        【 投影式 】Az1 = arctan2{ [cos φB sin ( λB- λA)] /

  [cos φA sin φB- sin φA cos φB cos ( λB- λA)] }

 d = (1/2) arccos [sin φA sin φB +

                                         cos φA cos φB cos ( λB- λA)]

φ1 = arcsin ( sin φA cos d + cos φA sin d cos Az1)

  λ0 = λA + arctan2 [sin d sin Az1 /

                              (cos φA cos d - sin φA sin d cos Az1)]

  Az2 = arctan2{ [ - cos φA sin ( λA- λ0)] /

 [sin φ1 cos φA cos ( λA- λ0) - cos φ1 sin φA] }

 cos z = sinφ1 sinφ + cosφ1 cosφ cos (λ - λ0)

 K = sec z = 1/cos z

 xi = RK cosφ sin(λ - λ0)

 yi = RK [cosφ1 sinφ - sinφ1 cosφ cos(λ - λo)]

 x = cos d (xi sin Az2 + yi cos Az2)

 y = yi sin Az2 - xi cos Az2

 Gnomonic (心射方位図法)と同様に cos z<0 は描画しない

         【経度・緯度】  経線:直線 、緯線:曲線

         【 ポイント 】・中心から離れるにつれ歪みますので、あまり広範囲の描画は

   できません。

             ・描画縦軸横軸は±3.0位内程度で描画しないと何を描画したか

                        わからないほど歪みます(サンプル描画の経線などの補助線

                         cos z<0適用しても x,y8,000 を超えることもあり

                         縦横軸を小さくしておかないと地図には見えません)。

  <基準経度・標準緯度・予備計算・共通数値 など>                
     記号  セルNo.         記述式                
   λA     C2   ???    中心経度A(希望経度A を入力)                
   λAラジアン     D2  =RADIANS(C2)                
   λB     C3   ???    中心経度B(希望経度B を入力)                
   λBラジアン     D3  =RADIANS(C3)                
   φA     C4     ??    中心緯度A(希望緯度A を入力)                
   φAラジアン     D4  =RADIANS(C4)                
   φB     C5     ??    中心緯度B(希望緯度B を入力)                
   φBラジアン     D5  =RADIANS(C5)                
                                                                         
  <予備計算 など>
     記号  セルNo.         記述式
     Az1     C2  =ATAN((COS($D$5)*SIN($D$3-$D$2))/(COS($D$4)*
                      SIN($D$5)-SIN($D$4)*COS($D$5)*COS($D$3-$D$2)))
 
     d     C3  =(1/2)*ACOS(SIN($D$4)*SIN($D$5)+
                                    COS($D$4)*COS($D$5)*COS($D$3-$D$2))
 
     φ1     C4  =ASIN(SIN($D$4)*COS($G$3)+COS($D$4)*SIN($G$3)*COS($G$2))
     λ0     C5  =D2+ATAN((SIN($G$3)*SIN($G$2))/(COS($D$4)*
                              COS($G$3)-SIN($D$4)*SIN($G$3)*COS($G$2)))
 
     Az2     J2  =ATAN((-COS($D$4)*SIN($D$2-$G$5))/(SIN($G$4)*COS($D$4)*
                                     COS($D$2-$G$5)-COS($G$4)*SIN($D$4)))
 
                                                                         
  <データ計算 など>  経度緯度のデータ毎に記述式を複写(行コピー)する。
     記号  セルNo.         記述式
      No.     B9   ???  ← 式を複写する時に、一旦ソートしたり、解析時に役立つので連番号を付与
     経度     C9   ???  ← 実際の経度データ
     緯度     D9   ???  ← 実際の緯度データ
     補正
  λ-λ
0
    E9  =IF($C$2<0,IF(C9-$C$2>180,C9-$C$2-360,C9-$C$2),
                                    IF(C9-$C$2<-180,C9+360-$C$2,C9-$C$2))
 
     cos z      F9  =SIN($G$4)*SIN(RADIANS(D9))+COS($G$4)*
                                          COS(RADIANS(D9))*COS(RADIANS(E9))
 
      xi     G9  =(COS(RADIANS(D9))*SIN(RADIANS(E9)))/F9
      yi     H9  =(COS($G$4)*SIN(RADIANS(D9))-SIN($G$4)*
                                     COS(RADIANS(D9))*COS(RADIANS(E9)))/F9
 
      x     I9  =COS($G$3)*(G9*SIN($J$2)+H9*COS($J$2))
      y     J9  =H9*SIN($J$2)-G9*COS($J$2)
   描画CH     K9  =IF(F9<0,"●",0) 

 

[6-6-14] 2点方位図法 ( Two-Point Azimuthal Projection

 

                              【地図基準点①】東経   0゚、北緯5128' ( グリニッジ,London )

                                                  【地図基準点②】東経 135゚、北緯3500' ( 日本ヘソ公園,西脇市 )

                              【経度間隔】15゚【緯度間隔】10

ダウンロード
6-6-14_Two-Point Azimuthal.pdf
PDFファイル 1.8 MB